Visual-Basic-Forum VB-Paradise.de

Visual Basic Quellcode

Set objShell = CreateObject("Shell.Application")
Set objFolder = objShell.Namespace("E:\alt\Dokumente") 
Set colItems = objFolder.Items
For each i in colItems
	i.InvokeVerbEx("Print")
Next

Visual Basic Quellcode

'PrintAll.vbs

'default directory
sSourceFolder = "E:\test"

'Executing the script with arguments will cause the very first argument (0) to replace the default
'directory defined in the script.
If WScript.Arguments.Count > 0 Then
	sSourceFolder = WScript.Arguments(0)
End If

Set fso = CreateObject("Scripting.FileSystemObject") '?

'If the directory does not exist, give an error messsage, else print all .xls files on the default printer.
If Not fso.FolderExists(sSourceFolder) Then
	WScript.Echo "Ordner " & sSourceFolder & " nicht verfügbar!"
	WScript.Quit(2)
Else
	bPrinted = False 'boolean value for checking whether any files were printed

	Set oShellApp = WScript.CreateObject("Shell.Application") '?

	For Each oFile In fso.GetFolder(sSourceFolder).Files
		If InstrRev(oFile.Name, ".") Then
			If LCase(Mid(oFile.Name, InstrRev(oFile.Name, "."))) = ".xls" Then 'print .xls files 
				oShellApp.ShellExecute oFile.Path, "", "", "print", 0
				bPrinted = True
				WScript.Sleep(5180)
			End If
		End If
	Next

	Set oShellApp = Nothing
	
	'Print a warning if no file was printed.
	If Not bPrinted Then
		WScript.Echo "Kein Dokument zum Drucken gefunden!"
		WScript.Quit(1)
	End If
End If