Ergebnisse in .txt schreiben

  • VBScript

Es gibt 1 Antwort in diesem Thema. Der letzte Beitrag () ist von peterfido.

    Ergebnisse in .txt schreiben

    Hallo Leute,
    brauche dringend Hilfe bei dem Script, das mir ein Bekannter zur Verfügung gestellt hat. Es liest sämtliche installierte Drucker etc. aus, und zeigt sie dann in einer HTML Datei an. Will das ganze allerdings so umgeschrieben haben, dass er nichts öffnet, sondern sämtliche Ergebnisse in eine .txt Datei auf der Platte speichert.

    HTML-Quellcode

    1. Set objNetwork = WScript.CreateObject("WScript.Network")
    2. strComputer = objNetwork.ComputerName
    4. On Error Resume Next
    6. Const wbemFlagReturnImmediately = &h10
    7. Const wbemFlagForwardOnly = &h20
    9. Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\CIMV2")
    10. Set colItems = objWMIService.ExecQuery("SELECT * FROM Win32_Printer", "WQL", _
    11. wbemFlagReturnImmediately + wbemFlagForwardOnly)
    14. For Each objItem In colItems
    15. txt = txt & "Drucker: " & objItem.Name & "<br>"
    16. Next
    18. Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\CIMV2")
    19. Set colItems = objWMIService.ExecQuery("SELECT * FROM Win32_OperatingSystem", "WQL", _
    20. wbemFlagReturnImmediately + wbemFlagForwardOnly)
    22. For Each objItem In colItems
    23. txt = txt & "Betriebssystem: " & objItem.Caption & "<br>"
    24. Next
    26. Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\CIMV2")
    27. Set colItems = objWMIService.ExecQuery("SELECT * FROM Win32_ComputerSystem", "WQL", _
    28. wbemFlagReturnImmediately + wbemFlagForwardOnly)
    30. For Each objItem In colItems
    31. txt = txt & "Domain: " & objItem.Domain & "<br>"
    32. txt = txt & "Username: " & objItem.UserName & "<br>"
    33. txt = txt & "RAM: " & objItem.TotalPhysicalMemory & "<br>"
    34. Next
    37. Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
    39. Set colItems = objWMIService.ExecQuery("SELECT IPAddress " & _
    40. "FROM Win32_NetworkAdapterConfiguration " & _
    41. "WHERE IPEnabled=TRUE")
    43. For Each objItem In colItems
    44. If Not IsNull(objItem.IPAddress) Then
    45. For i = LBound(objItem.IPAddress) To UBound(objItem.IPAddress)
    46. txt = txt & "IP-Adresse: " & objItem.IPAddress(i) & "<br>"
    47. Next
    48. End If
    49. Next
    51. ShowMSIE txt, title
    53. Sub ShowMSIE (txt, title)
    55. Dim oIE, oDoc
    57. Set oIE = WScript.CreateObject("InternetExplorer.Application")
    58. oIE.left=20
    59. oIE.top = 50
    60. oIE.height = 380
    61. oIE.width = 480
    62. oIE.menubar = 0
    63. oIE.toolbar = 0
    64. oIE.statusbar = 0
    65. oIE.navigate ("about:blank")
    66. oIE.visible = 1
    68. Set oDoc = oIE.Document
    69. oDoc.open
    70. oDoc.writeln ("<html><head><title>" & title & "</title></head>")
    71. oDoc.writeln ("<body>" & Txt & "</body></html>")
    72. oDoc.close
    74. End Sub

    Visual Basic-Quellcode

    1. Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\CIMV2")
    2. Set colItems = objWMIService.ExecQuery("SELECT * FROM Win32_Printer", "WQL", _
    3. wbemFlagReturnImmediately + wbemFlagForwardOnly)
    6. For Each objItem In colItems
    7. txt = txt & "Drucker: " & objItem.Name & VBCRLF
    8. Next
    10. Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\CIMV2")
    11. Set colItems = objWMIService.ExecQuery("SELECT * FROM Win32_OperatingSystem", "WQL", _
    12. wbemFlagReturnImmediately + wbemFlagForwardOnly)
    14. For Each objItem In colItems
    15. txt = txt & "Betriebssystem: " & objItem.Caption & VBCRLF
    16. Next
    18. Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\CIMV2")
    19. Set colItems = objWMIService.ExecQuery("SELECT * FROM Win32_ComputerSystem", "WQL", _
    20. wbemFlagReturnImmediately + wbemFlagForwardOnly)
    22. For Each objItem In colItems
    23. txt = txt & "Domain: " & objItem.Domain & VBCRLF
    24. txt = txt & "Username: " & objItem.UserName & VBCRLF
    25. txt = txt & "RAM: " & objItem.TotalPhysicalMemory & VBCRLF
    26. Next
    29. Set objWMIService = GetObject("winmgmts:\\" & strComputer & "\root\cimv2")
    31. Set colItems = objWMIService.ExecQuery("SELECT IPAddress " & _
    32. "FROM Win32_NetworkAdapterConfiguration " & _
    33. "WHERE IPEnabled=TRUE")
    35. For Each objItem In colItems
    36. If Not IsNull(objItem.IPAddress) Then
    37. For i = LBound(objItem.IPAddress) To UBound(objItem.IPAddress)
    38. txt = txt & "IP-Adresse: " & objItem.IPAddress(i) & VBCRLF
    39. Next
    40. End If
    41. Next
    42. N = Len(Wscript.scriptname)
    43. Pfad = Left(Wscript.scriptfullname, Len(Wscript.scriptfullname) - N)
    44. Dateiname = Pfad & "Druckerliste.txt"
    45. Set fso = CreateObject("Scripting.FileSystemObject")
    46. Set oFile = fso.OpenTextFile(Dateiname,2,true)
    47. oFile.Write txt
    48. oFile.close
    Gruß
    Peterfido

    Keine Unterstützung per PN!

Facebook
Telefonspende