Emails nicht farbig drucken???

TomWi · 4. September 2015, 07:19

Hallo Forum,

gibt es eine Möglichket, dass die Emails aus Outlook heraus nicht farbig gedruckt werden, ohne jedesmal in die Druckereinstellungen gehen zu müssen um Graustufendruck einzustellen?
Wie gesagt, das soll nur für Outlook gültig sein, bei allen anderen Programmen soll weiterhin farbig gedruckt werden.

Danke im Voraus für Eure Hilfe.

Tom

mumpel · 6. September 2015, 10:37

Hallo!

Nicht ohne VBA, und dann auch nicht in Outlook. Man müsste hier den Umweg über Word nehmen, hat dann allerdings den in Outlook üblichen Header nicht. Oder mal im Internet nach passenden Tools suchen. Du kannst auch einen Programmierer beauftragen der Dir ein passendes Tool erstellt.

Gruß, René

Drahuverar · 7. September 2015, 08:37

Was du machen könntest:
Drucker erneut hinzufügen und SW (Schwarz-Weiß) nennen. Den stellst du so ein wie du es brauchst.
Jetzt (müsste ich bei Gelegenheit testen) müsstest du ein Makro aufzeichnen (In WORD!) und dann machst du dir einen neuen Button in Outlook, den nennst du dann SW Druck.
Hinterlege in dem Makro einfach den neu-erstellten Drucker... Outlook ist da etwas knifflig, aber:
Im Grunde sollte das so gehen~

Edit: Ist doch ziemlich anspruchsvoll..Habe gerade eine halbe Stunde etwas versucht, ohne auf ein Ergebnis zu kommen.

Grüße,
Drahuverar

mumpel · 7. September 2015, 10:09

Drahuverar schrieb:

(...) Drucker erneut hinzufügen und SW (Schwarz-Weiß) nennen. Den stellst du so ein wie du es brauchst (...)

Wenn man es so macht benötigt man Word nicht, sondern kann auch direkt in Outlook drucken.

Visual Basic-Quellcode

Public Sub PrintMailBlack()
Dim olMailItem As Outlook.MailItem
Select Case True
Case TypeOf Application.ActiveWindow Is Outlook.Inspector
Set olMailItem = Application.ActiveInspector.CurrentItem
Case Else
With Application.ActiveExplorer.Selection
If .Count Then Set olMailItem = .Item(1)
End With
If olMailItem Is Nothing Then Exit Sub
End Select
' Name des SW-Druckers angeben. Drucker wird umgestellt
Shell "rundll32 printui.dll,PrintUIEntry /y /n ""SW-Drucker""" ' Name des SW-Druckers
' Aktive Email drucken
olMailItem.PrintOut
' Name des Standarddruckers angeben. Standarddrucker wird wiederhergestellt
Shell "rundll32 printui.dll,PrintUIEntry /y /n ""Samsung ML-2850 Series""" ' Name des SW-Druckers
End Sub

Drahuverar · 7. September 2015, 10:35

Das ist doch mal 'ne feine Sache. Bin ein totaler Greenhorn darin, hätte sicherlich ewig gesucht.

mumpel · 7. September 2015, 11:18

Man kann auch über Word drucken. In diesem Beispiel verliert man allerdings auch alle Bilder. Der Header fehlt natürlich. Ein Verweis auf die Word-Object-Library muss gesetzt werden.

Visual Basic-Quellcode

Public Sub PrintAPageFromEmail()
Dim Ins As Outlook.Inspector
Dim obj As Outlook.MailItem
Dim wdApp As Word.Application
Dim wdDoc As Word.Document
Dim wdRange As Word.Range
Dim wdOldPrinter As String
Select Case True
Case TypeOf Application.ActiveWindow Is Outlook.Inspector
Set obj = Application.ActiveInspector.CurrentItem
Case Else
With Application.ActiveExplorer.Selection
If .Count Then Set obj = .Item(1)
End With
If obj Is Nothing Then Exit Sub
End Select
Set Ins = obj.GetInspector
Set wdDoc = Ins.WordEditor
Set wdRange = wdDoc.Range
wdRange.WholeStory
wdRange.Copy
Set wdApp = New Word.Application
With wdApp
.Visible = True
.Documents.Add
With .ActiveDocument
If Not wdDoc Is Nothing Then
.PageSetup.RightMargin = 42.55
.PageSetup.LeftMargin = 42.55
.PageSetup.TopMargin = 70.85
.PageSetup.BottomMargin = 56.7
End If
.Range(0, 0).PasteAndFormat wdFormatPlainText
.PrintOut copies:=1
.Close SaveChanges:=False
End With
.Quit
End With
End Sub

TomWi · 8. September 2015, 18:45

@mumpel
vielen Dank, das ist genau das, was ich gesucht habe. Jetzt kann ich die Farbtoner ein bisschen schonen.

Tom

Emails nicht farbig drucken???

Emails nicht farbig drucken???

Drahuverar schrieb:

Visual Basic-Quellcode

Visual Basic-Quellcode

Benutzer online 1

Ähnliche Themen

3 Benutzer haben hier geschrieben