Excel, automatisch Outlook öffnen und E-Mail generieren.

  • Excel

Es gibt 7 Antworten in diesem Thema. Der letzte Beitrag () ist von volti.

    Excel, automatisch Outlook öffnen und E-Mail generieren.

    Hallo Zusammen,


    wenn das Makro ausgeführt wird, wird die entsprechende Zeile durch die Artikelnummer gefunden und aus dieser Tabelle in ein anderes Tabellenblatt übertragen.

    Ich möchte das Outlook geöffnet wird und ein paar konstante aber auch variable Werte in die Betreffzeile als auch in die E-Mail geschrieben werden.
    Beispiel Betreffzeile: Artikel C3 C6 C8 wurde fertiggestellt

    Bei den C3,6,8 handelt sich es um die variablen die ja nicht immer in C stehen sondern entsprechend der richtigen Zeile über das Makro oben zugewiesen werden müssen.
    Des weiteren würde ich gerne noch einen E-Mail Text vorgeben, die E-Mail kann durch den Anwender noch kontrolliert werden und muss anschließend manuelle versendet werden.

    Wie kann ich das ganze am besten lösen?

    Visual Basic-Quellcode

    1. Sub AuftragFertigBuchen()
    3. Dim Eingabe As Variant
    4. Dim finden As Range
    5. Dim SpalteErledigtAm As Integer
    6. SpalteErledigtAm = 6
    8. Set wbDatenÜbersicht = ThisWorkbook.Worksheets("Daten-Übersicht")
    9. Set wbBearbAufträge = ThisWorkbook.Worksheets("bearbeitete Aufträge")
    11. AnzahlSpaltenOV = 22 'Anzahl genutzter Spalten bei "Daten-Übersicht" (OverView/OV)
    13. 'Eingabe des Auftrages. Vorauswahl abhängig von der aktiven/ausgewählten Zelle
    14. Eingabe = InputBox("Welcher Auftrag soll fertig gebucht werden?", "Auftrag buchen", ActiveCell.Value)
    15. If Eingabe <> "" Then
    17. Set finden = wbDatenÜbersicht.Range("C3:C13000").Find(what:=Eingabe, LookAt:=xlWhole) 'in welcher zelle steht die Auftragsnummer?
    19. If Cells(finden.Row, SpalteErledigtAm) <> "" Then
    21. If Not finden Is Nothing And IsEmpty(finden) = False Then 'Überprüfung, ob zu dem eingegebenen Wert eine Zeile gefunden wurde
    22. wbBearbAufträge.Rows(2).Insert 'neue 3.Zeile einfügen
    23. wbDatenÜbersicht.Rows(finden.Row).Copy Destination:=wbBearbAufträge.Range("A2") 'Kopieren der Zeile in "bearbeitete Aufträge"
    24. wbDatenÜbersicht.Rows(finden.Row).Delete 'Löschen der Zeile aus "Daten-Übersicht"
    25. Else
    26. MsgBox "Der eingegebene Auftrag ist nicht in der Liste enthalten. Bitte erneut eingeben."
    27. End If
    28. Else
    29. MsgBox "Der Auftrag kann ohne Enddatum nicht fertig gebucht werden"
    30. End If
    32. End If
    34. Application.ScreenUpdating = True
    35. End Sub

    Für das Versenden eine E-Mail mit Outlook kannst Du dieses Modul nutzen.

    Visual Basic-Quellcode

    1. Option Explicit
    2. Option Private Module
    4. Public olApp As Outlook.Application
    6. ' Der Verweis auf Outlook muss gesetzt sein
    8. ' strTo - Empfängeradresse ggf. durch Semikolon getrennt
    9. ' Subject - Betreff
    10. ' Body - Der Text der E-Mail, falls HTML mit HTML-Formatierung für day Layout
    11. ' CC - Empfängeradresse in CC ggf. durch Semikolon getrennt
    12. ' BCC - Empfängeradresse in BCC ggf. durch Semikolon getrennt
    13. ' Importance - Wichtigkeit 1- normal, 2 - hoch
    14. ' HTML - True E-Mail mit Outlook-Signatur, False E-Mail mit Nur Text
    15. ' Display - True zeigt die E-Mail an, False versendet die E-Mail direkt
    16. ' Attachements - Array mit für Anlagen, die Datei muss mit dem kompletten Pfad angegebnen werden
    17. Public Sub SendEmail(ByVal strTo As String, ByVal Subject As String, ByVal Body As String, _
    18. Optional ByVal CC As String = "", Optional ByVal Bcc As String = "", Optional ByVal Importance As Integer = 1, _
    19. Optional HTML As Boolean = False, Optional Display As Boolean = False, Optional ByVal Attachments As Variant)
    21. On Error GoTo ErrHandling
    23. Dim olMail As Outlook.MailItem
    24. Dim olOldbody As String
    26. If olApp Is Nothing Then
    27. Set olApp = GetObject(, "Outlook.Application")
    28. End If
    30. Set olMail = olApp.CreateItem(olMailItem)
    32. With olMail
    33. .To = strTo
    34. .CC = CC
    35. .Bcc = Bcc
    36. .Subject = Subject
    37. .Importance = Importance
    39. If isArrayEmpty(Attachments) = False Then
    41. Dim strFile As Variant
    43. For Each strFile In Attachments
    45. If FileExists(strFile) = True Then
    46. .Attachments.Add strFile
    47. Else
    48. Dim intPos As Integer
    49. Dim part() As String
    50. str = Replace(strFile, "/", "\")
    51. part = Split(strFile, "\")
    52. MsgBox "Die Datei '" & part(UBound(part)) & "' konnte nicht gefunden werden."
    53. End If
    55. Next
    57. End If
    59. 'HTML ergibt eine E-Mail mit Outlook-Signatur
    60. If HTML Then
    61. olOldbody = .HTMLBody
    62. .HTMLBody = "<html><body>" & Body & olOldbody
    63. Else
    64. .Body = Body
    65. End If
    67. If Display Then
    68. .Display
    69. .GetInspector.Display
    70. Else
    71. .Send
    72. End If
    73. End With
    75. Set olMail = Nothing
    76. Exit Sub
    78. ErrHandling:
    80. Select Case Err.Number
    81. Case 429
    82. Set olApp = CreateObject("Outlook.Application")
    83. Resume Next
    84. Case Else
    85. MsgBox "Fehler bein E-Mail versenden" & vbNewLine & Err.Number & " " & Err.Description
    86. On Error GoTo -1
    87. End Select
    88. End Sub
    90. Public Function FileExists(ByVal strFilePath As String) As Boolean
    91. FileExists = False
    92. On Error Resume Next
    93. If Not Dir(strFilePath) = vbNullString And Not strFilePath = vbNullString Then
    94. FileExists = True
    95. End If
    96. End Function


    Die Prozedur SendEmail benötigt mindestens den Empfänge, den Betreff und den E-Mail-Text.
    Es wird geprüft, ob Outlook geöffnet ist, ansonsten wird Outlook gestartet.
    Ich habe daraus ein Tutorial gemacht: E-Mail über Outlook versenden
    NB. Es ist doch schön, wenn man lesbare Namen vergibt. Siehe auch [VB.NET] Beispiele für guten und schlechten Code (Stil).

    Dieser Beitrag wurde bereits 2 mal editiert, zuletzt von „INOPIAE“ ()

    Schon mal danke dafür, aber dies löst mein Problem die Betreffzeile variabel zu füllen nicht.

    Ich möchte doch wie oben beschrieben, verschiedene Zellen in die Betreffzeile schreiben, je nachdem welche Auftragsnummer gewählt wurde.
    Wie kann ich dies umsetzen?


    So kann ich die entsprechende Zeile in der die Auftragsnummer steht finden.

    Wie kann ich jetzt die entsprechenden Zellen z.B. 6,7,10 ansprechen und in die Betreffzeile der E-Mail schreiben?

    Visual Basic-Quellcode

    1. Set finden = wbDatenÜbersicht.Range("C3:C13000").Find(what:=Eingabe, LookAt:=xlWhole) 'in welcher zelle steht die Auftragsnummer?


    Beiträge zusammengefügt. ~Thunderbolt

    Dieser Beitrag wurde bereits 1 mal editiert, zuletzt von „Thunderbolt“ ()

    Versuchs mal so, wenn Dein Code den Auftrag gefunden hat:

    Visual Basic-Quellcode

    1. Dim zeile As Long
    2. zeile = finden.row
    4. Dim Subject As String
    5. Subject = "Hier die Daten zu " & wbDatenÜbersicht.cells(zeile,6) &" " & wbDatenÜbersicht.cells(zeile,7) &" " & wbDatenÜbersicht.cells(zeile,10)
    NB. Es ist doch schön, wenn man lesbare Namen vergibt. Siehe auch [VB.NET] Beispiele für guten und schlechten Code (Stil).

    INOPIAE schrieb:


    Public olApp As Outlook.Application

    ' Der Verweis auf Outlook muss gesetzt sein

    Ich würde auf Early-Binding verzichten. Stattdessen Late-Binding nutzen.

    VB.NET-Quellcode

    1. Sub Test()
    2. Dim olApp as Object
    4. Set olApp = CreateObject("Outlook.Application")
    5. With olApp.CreateItem(0)
    7. End With
    8. End Sub

    Super danke für eure Hilfe! Es hat funktionier und das Tutorial ist mega.

    Eine laienhafte Frage müsst Ihr mir noch zugestehen. :)
    Was spricht dagegen, den E-Mail Versand mit so einem simplen Code umzusetzen?

    Visual Basic-Quellcode

    1. ​
    2. Set MyOutApp = CreateObject("Outlook.Application")
    3. Set MyMessage = MyOutApp.CreateItem(0)
    4. With MyMessage
    5. .To = Range("A1")
    6. .Subject = (Subject)
    7. .body = "Hallo," & vbCrLf & vbCrLf & "anbei der Link zu dem im Betreff genannten Artikeln."
    8. .Display
    10. End With
    11. Set MyOutApp = Nothing
    12. Set MyMessage = Nothing

    Thepinky schrieb:

    .body = "Hallo," & vbCrLf & vbCrLf & "anbei der Link zu dem im Betreff genannten Artikeln."


    Ich sehe hier keinen Link, auf den Du verweist.

    Die Funktion, die ich Dir gegeben habe, kann in einem größeren Projekt immer wieder aufgerufen werden, ohne das man den Code noch einmal anpassen muss. Die Funktion deckt auch alle Möglichkeiten beim Versand einer E-Mail mit ab.
    Da ich faul bin, habe ich diesen Code in einem Modul, dass ich bei Bedarf, dann einfach in das Projekt importiere. Dann brauche ich nur noch die Funktion SendEmail mit den notwendigen Parametern aufrufen und ich bin fertig.

    Wenn Dir Dein Code reicht, ist ja alles in Ordnung.
    NB. Es ist doch schön, wenn man lesbare Namen vergibt. Siehe auch [VB.NET] Beispiele für guten und schlechten Code (Stil).

    Hallo zusammen,

    mir reicht's auch so incl. Signatur

    VB.NET-Quellcode

    1. Sub Mail()
    2. With CreateObject("Outlook.Application").CreateItem(0)
    3. .Getinspector.Display
    4. .To = Range("A1")
    5. .Subject = (Subject)
    6. .body = "Hallo," & vbCrLf & vbCrLf & "anbei der Link zu dem im Betreff genannten Artikeln." _
    7. & vbCrLf & .body ' Optional mit Signatur
    8. End With
    9. End Sub

    Gruß KH

Facebook
Telefonspende