Webseiteninhalt/HTML auslesen oder auf externe MySQL-Daten via PHP zugreifen

    • VB6

      [Internet] Webseiteninhalt/HTML auslesen oder auf externe MySQL-Daten via PHP zugreifen

      Wie kann ich den HTML-Code bzw Webseiteninhalt einer URL/Adresse in einen String auslesen?
      Wie kann ich auf die Daten von einem externen MySQL-Server via PHP und VB zugreifen?

      Visual Basic-Quellcode

      1. Private Declare Function InternetCloseHandle Lib "wininet.dll" _
      2. (ByVal hInternetHandle As Long) As Boolean
      3. Private Declare Function InternetOpenA Lib "wininet.dll" (ByVal lpszCallerName As String, _
      4. ByVal dwAccessType As Long, ByVal lpszProxyName As String, ByVal lpszProxyBypass As _
      5. String, ByVal dwFlags As Long) As Long
      6. Private Declare Function InternetOpenUrlA Lib "wininet.dll" (ByVal hOpen As Long, ByVal _
      7. sUrl As String, ByVal sHeaders As String, ByVal lLength As Long, ByVal lFlags As Long, _
      8. ByVal lContext As Long) As Long
      9. Private Declare Function InternetReadFile Lib "wininet.dll" (ByVal hFile As Long, ByVal _
      10. sBuffer As String, ByVal lNumBytesToRead As Long, Bytes As Long) As Integer
      12. Public Enum InternetOpenType
      13. IOTPreconfig = 0
      14. IOTDirect = 1
      15. IOTProxy = 3
      16. End Enum
      18. Public Function OpenURL(ByVal URL As String, Optional ByVal OpenType As _
      19. InternetOpenType = IOTPreconfig) As String
      20. Const INET_RELOAD = &H80000000
      21. Dim hInet As Long
      22. Dim hURL As Long
      23. Dim Buffer As String * 2048
      24. Dim Bytes As Long
      25. 'Inet-Connection öffnen:
      26. hInet = InternetOpenA("VB-Tec:INET", OpenType, vbNullString, vbNullString, 0)
      27. hURL = InternetOpenUrlA(hInet, URL, vbNullString, 0, INET_RELOAD, 0)
      28. 'Daten sammeln:
      29. Do
      30. InternetReadFile hURL, Buffer, Len(Buffer), Bytes
      31. If Bytes = 0 Then Exit Do
      32. OpenURL = OpenURL & Left$(Buffer, Bytes)
      33. Loop
      34. 'Inet-Connection schließen:
      35. InternetCloseHandle hURL
      36. InternetCloseHandle hInet
      37. End Function
      39. Private Sub Command1_Click()
      40. MsgBox OpenURL("http://www.deineDomain.de/Datei.php?parameter=wert", IOTDirect)
      41. End Sub



      Keywords: Visual Basic 6, VB 6, Internet, Download, PHP, DB, URL, Quelltext, API, InternetOpen, InternetOpenUrl, InternetReadFile, InternetCloseHandle, Function OpenURL, Website in String
      Gruß, Agent Smith 8-)

      activeFlags = (lazy OR weary)

      Lemgo-Verschwörung | Mathematics | VB-Paradise in blau

      Dieser Beitrag wurde bereits 3 mal editiert, zuletzt von „Mad Andy“ ()

    Facebook
    Telefonspende