MCI send string mit mp3 - Lautstärkeregler?

  • VB6

Es gibt 8 Antworten in diesem Thema. Der letzte Beitrag () ist von c.m.obrecht.

    MCI send string mit mp3 - Lautstärkeregler?

    Ich versuchte heute den ganzen Tag einen Lautstärkeregler einzubauen. Ich setzte dazu einen VScroll ein und fügte Code beim Change-Ereignis ein, die Funktionen wurden auf dem Form oder im separaten Modul mit den MCI-Funktionen eingefügt. Habe sämtliche (!) bei Google auffindbaren (jedenfalls mit meinen Suchbegriffen) Beispiele probiert aber ich schaffte es nicht. Wie könnte ich den Code um einen Lautstärkeregler (und toll wäre einen Balken, der die Position anzeigt und verschoben werden kann zum spulen, wie beim WMP) ergänzen?
    Vielen Dank!
    Habe bisher folgenden Code:

    Visual Basic-Quellcode

    1. Private Sub Command1_Click()
    2. On Error GoTo err
    3. MP3_Play sFilename, "MyAlias"
    5. err:
    6. End Sub
    8. Private Sub Command2_Click()
    9. On Error Resume Next
    10. MP3_Stop "MyAlias"
    11. End Sub
    13. Private Sub Command3_Click()
    14. With CommonDialog1
    15. .Filter = "mp3 Dateien *.mp3|*.mp3"
    17. .ShowOpen
    18. sFilename = .filename
    19. End With
    20. Label1.Caption = sFilename
    21. MP3_Stop "MyAlias"
    22. MP3_Play sFilename, "MyAlias"
    23. Exit Sub
    24. err: MsgBox "Wiedergabe nicht möglich", vbCritical, "Fehler"
    25. End Sub
    28. Private Sub Command4_Click()
    29. frmAbout.Show
    30. End Sub
    32. Private Sub Form_Load()
    33. On Error Resume Next
    34. If Command$ <> "" Then
    35. ' Annahme: Es wurde eine Datei angegeben,
    36. ' die ausgelesen und in einer TextBox angezeigt
    37. ' werden soll
    39. Dim sInhalt As String
    41. ' Evtl. vorhandene Anführungszeichen entfernen
    43. sFilename = Replace(Command$, Chr$(34), "")
    44. On Error GoTo 0
    46. End If
    48. On Error GoTo err
    49. MP3_Play sFilename, "MyAlias"
    50. Label1.Caption = sFilename
    52. err:
    53. End Sub
    56. Private Sub Form_Unload(Cancel As Integer)
    57. MP3_Stop "MyAlias"
    58. End Sub

    sowie

    Visual Basic-Quellcode

    1. ' Modul MP3-Play and Stop via API
    2. Option Explicit
    4. ' zunächst die benötigte API-Deklaration
    5. Private Declare Function mciSendString Lib "winmm.dll" _
    6. Alias "mciSendStringA" (ByVal lpszCommand As String, _
    7. ByVal lpszReturnString As String, _
    8. ByVal cchReturnLength As Long, _
    9. ByVal hwndCallback As Long) As Long
    11. Private Declare Function GetShortPathName Lib "kernel32" _
    12. Alias "GetShortPathNameA" (ByVal lpszLongPath As String, _
    13. ByVal lpszShortPath As String, _
    14. ByVal cchBuffer As Long) As Long
    15. ' MP3-Datei abspielen
    16. Public Function MP3_Play(ByVal sFile As String, _
    17. ByVal sAlias As String) As Boolean
    19. Dim bResult As Boolean
    21. ' Dateinamen in DOS 8.3 Format, da z.B. Sonderzeichen
    22. ' wie Leerzeichen Probleme machen
    23. Dim sBuffer As String
    24. Dim lResult As Long
    26. sBuffer = Space$(255)
    27. lResult = GetShortPathName(sFile, sBuffer, Len(sBuffer))
    29. If lResult <> 0 Then
    30. sFile = Left$(sBuffer, InStr(sBuffer, vbNullChar) - 1)
    32. ' MCI öffnen
    33. lResult = mciSendString("open " & sFile & _
    34. " type MPEGVideo alias " & sAlias, 0, 0, 0)
    36. If lResult = 0 Then
    37. ' MP3 abspielen
    38. If mciSendString("play " & sAlias & _
    39. " from 0", 0, 0, 0) = 0 Then
    40. bResult = True
    41. End If
    42. End If
    43. End If
    45. MP3_Play = bResult
    46. End Function
    49. ' Wiedergabe stoppen und MCI schließen
    50. Public Sub MP3_Stop(ByVal sAlias As String)
    51. mciSendString "stop " & sAlias, 0, 0, 0
    52. mciSendString "close " & sAlias, 0, 0, 0
    53. End Sub

    Visual Basic-Quellcode

    1. ' Lautstärke setzen
    2. Public Sub mciSetVol(ByVal strAlias As String, ByVal nVolume As Long)
    3. On Error Resume Next
    4. If nVolume < 0 Or nVolume > 2000 Then Exit Sub
    5. mciSendString "setaudio " & strAlias & " volume to " & CStr(nVolume * 10), 0, 0, 0
    6. End Sub
    8. ' Aktuelle Position ermitteln
    9. Public Function mciCurPos(ByVal strAlias As String) As Long
    10. Dim sBuffer As String * 255
    12. On Error Resume Next
    13. mciSendString "status " & strAlias & " position", sBuffer, Len(sBuffer), 0
    14. mciCurPos = Val(sBuffer)
    15. End Function
    16. ' Gesamtspielzeit ermitteln
    17. Public Function mciGetLength(ByVal strAlias As String) As Long
    18. Dim sBuffer As String * 255
    20. On Error Resume Next
    21. mciSendString "status " & strAlias & " length", sBuffer, Len(sBuffer), 0
    22. mciGetLength = Val(sBuffer)
    23. End Function


    Bei dem Playbefehl kannst du die Position mit angeben.
    Gruß
    Peterfido

    Keine Unterstützung per PN!

    Vielen vielen Dank!

    Habe das mit dem Lautstärkeregler hingekriegt; und einen Balken der läuft auch, nun habe ich 2 Probleme noch:
    - wollte

    Visual Basic-Quellcode

    1. slider2.max = mciGetLength("MyAlias")

    einsetzen, wie ich bei mciCurPos erfolgreich den Balken in Bewegung bringe; dass der Balken auch unabhängig bei jedem Lied bis zum Schluss läuft. Aber da kommt immer "ungültiger Eigenschaftswert"; habe auch schon mit umwandeln in integer usw versucht.

    2. wie kann ich die Position verändern, bei Bewegung des Balkens?

    Danke :)

    Ich selbst rechne soetwas immer in Promille um, also den Maxwert auf 1000 und intern dann die entsprechende Position errechnen. Mal Dateigröße durch 1000 quasi.

    Zu 2. Sieh dir mal den Playbefehl genauer an, da steht etwas von from 0 ...
    Gruß
    Peterfido

    Keine Unterstützung per PN!

    Dieser Beitrag wurde bereits 1 mal editiert, zuletzt von „peterfido“ ()

    Ach so, also dass der Max-Wert dann auf Dateigrösse/1000 gesetzt wird; gibt es sonst zu grosse Zahlen? So etwas ähnliches habe ich probiert aber werde ich nochmals tun, vielleicht habe ich auch nur 100 genommen.

    Das habe ich gesehen; ich versuchte einen modifizierten Play-Befehl einzubauen welcher aufgerufen wird wenn der Slider bewegt wird, und den Wert des Sliders übergibt als Startwert; aber bin nicht sicher ob ich das richtig gemacht habe, jedenfalls startete das Lied ganz von Neuem ?(

    Das ist meine Promillesetzfunktion:

    Visual Basic-Quellcode

    1. Public Sub SetProzent(ByVal Prozent As Integer)
    2. Dim p As Long
    3. Dim Laenge As Long
    5. Laenge = mciGetLength(chan) / 1000
    7. If Laenge > 0 And Prozent >= 0 And Prozent <= 1000 Then
    8. p = Laenge * Prozent
    9. mciPlay chan, p
    10. NeuesLied = False
    11. End If
    12. End Sub


    Und das mein mciPlay Sub:

    Visual Basic-Quellcode

    1. Public Sub mciPlay(ByVal strAlias As String, Optional nFromPos As Long = 0)
    2. On Error Resume Next
    3. mciSendString "play " & strAlias & " from " & CStr(nFromPos), 0, 0, 0
    4. mciSendString "put " & strAlias & " destination", 0, 0, 0
    5. End Sub
    Gruß
    Peterfido

    Keine Unterstützung per PN!

    Super, das Position-Setzen funktioniert nun. Zuerst hatte ich einen "Zirkelbezug" erstellt da der Slider ja selbständig bewegt wird :D Nun geht es aber, nur die Länge ist noch immer fest (ist für diese Funktion natürlich wichtig); die GetLength - Funktion hatte ich nicht hinbekommen; was muss ich als Prozentzahl übergeben, wo soll die herkommen? Habe verschiedenes versucht, doch egal was ich dem Slider als MAX-Wert im Code gebe, es kommt immer "ungültiger Eigenschaftswert".

Facebook
Telefonspende