Word-Dokument. Eine GLOBAL hochzählende Nummer

  • Word

Es gibt 12 Antworten in diesem Thema. Der letzte Beitrag () ist von Manschula.

    Word-Dokument. Eine GLOBAL hochzählende Nummer

    Hi,

    ich schicke vorab... Ich kann VB.Net, VB6, Java usw. aber KEIN VBA XD
    Trotzdem habe ich jetzt ein Problem was ich hoffentlich mit VBA lösen kann.

    Es geht darum. Hier im Hause gibt es so genannte "Handlieferscheine". Auf diesen ist eine EINDEUTIGE Nummer. Das heißt... Ich muss in einem Word-Formular an der entsprechenden Stelle eine Nummer haben die immer beim öffnen der Vorlage (.dot) um 1 hochgezählt wird. Diese Vorlage wird auf dem Server hier gelagert und ALLE Mitarbeiter greifen auf genau diese zu.

    KANN man sowas über VBA lösen und wenn ja... hat jemand dazu ne kleine Info für mich wie?
    Es war einmal ein kleiner Bär... der wollte eine Geschichte hörn... Da erzählte ihm seine Mutti:
    Es war einmal ein kleiner Bär... der wollte eine Geschichte hörn... Da erzählte ihm seine Mutti:
    Es war einmal ein kleiner Bär... der wollte eine Geschichte hörn... Da erzählte ihm seine Mutti:
    ... Nun solltest es selber wissen. :'D

    MemoAnMichSelbst schrieb:

    KANN man sowas über VBA lösen und wenn ja... hat jemand dazu ne kleine Info für mich wie?

    Moin,

    ja, das geht.
    Z.B. so:

    Spoiler anzeigen

    Visual Basic-Quellcode

    1. Sub AutoOpen()
    2. Dim nCounter As Long
    4. nCounter = ActiveDocument.Bookmarks("counter").Range
    5. nCounter = nCounter + 1
    7. ReplaceBookmarkText ActiveDocument, "counter", CStr(nCounter)
    8. End Sub
    10. Sub ReplaceBookmarkText(oDoc As Document, strBMName As String, strBMText As String)
    11. Dim rng As Range
    13. If oDoc.Bookmarks.Exists(strBMName) Then
    14. Set rng = oDoc.Bookmarks(strBMName).Range
    15. rng.Text = strBMText
    16. oDoc.Bookmarks.Add strBMName, rng
    17. Set rng = Nothing
    18. End If
    19. End Sub


    Anbei noch ein Worddokument als Anhang, wo dies umgesetzt ist.
    Wenn Du die Vorlage mit dem Windows-Explorer öffnest (rechte Maustaste -> Kontextmenü -> öffnen), dann startet das Makro und zählt die Zahl im Dokument um 1 hoch.
    Makros müssen natürlich zugelassen sein und die Sicherheitsstufe muss ganz runter.

    Viel Spaß beim Experimentieren,
    Bruno
    Dateien

    • vorlage.zip

      (8,84 kB, 524 mal heruntergeladen, zuletzt: )

    Hi und danke für die Hilfe.

    Der Code sieht für mich als Laien erstmal sinnvoll aus.
    Du hast ne Routine "AutoOpen" erstellt die einen Counter "nCounter" immer um eins nach oben zählt wenn sie ausgeführt wird.
    Ich weiß nicht ob du AutoOpen erstellt hast, oder ob das eine Funktion vom Word ist, wie zB. in VB das Form_Load. Da es aber von dir nirgends augerufen wird, denke ich dass es dem Form_Load ähnlich ist.
    Dann führst du in dieser Routine eine weitere Routine zum überschreiben des Bookmarks aus, welcher mit dem neuen Counter gefüllt wird.
    Die Routine zum schreiben des Bookmarks ist soweit verständlich.

    Nun habe ich beim Testen jedoch das Problem!? dass in der .dot immer "1007" steht. Wenn ich diese als doc unter anderem Namen speichere macht er mir ne 1008 raus. Wenn ich diese .doc nochmals öffne, bleibt weiterhin 1008 stehen.

    Ich benötige ja, dass er bei jedem Start einen Wert um eins hoch zählt. Und soweit ich das verstehe macht der Code ja auch genau das. Er greift sich den aktuell gesetzten Wert ab und überschreibt ihn. Und ich denke hier ist der Knackpunkt. Die .dot wird ja nie gespeichert. Meist wird das Ding ja aufgerufen, ausgefüllt und dann gedruckt.
    Ich hoffe das war soweit verständlich ^^

    Könnte man in der Funktion hinterlegen, dass er direkt nach dem Start und dem hochzählen die dot speichert und somit der Wert hochgezählt wäre?

    Und nochmals... Danke für die Hilfe. Ich verstehe zwar die Syntax einigermaßen, aber die Vokabeln fehlen mir ;)

    Meine erste Idee war

    Visual Basic-Quellcode

    1. ActiveDocument.Save
    direkt in der AutoOpen Routine nach dem ReplaceBookmarkText auszuführen. Aber das hilft wohl nicht.

    Dann dachte ich... ermittel den Dateipfad... der wird bei Save sicher ne Doc schreiben... Aber wenn ich

    Visual Basic-Quellcode

    1. Application.ActiveDocument.FullName
    abfrage wirft er mir auch Dokument1 zurück und nicht den Pfad der .dot Datei.

    Eine andere alternative wäre ja eine hinterlegte .txt Datei oder ähnliches, in welche der Wert steht und welche immer nur kurz ausgelesen wird. Dieser Wert wird dann um 1 hochgezählt in die txt zurückgeschrieben und ins Word-Formulat geschrieben.
    Es war einmal ein kleiner Bär... der wollte eine Geschichte hörn... Da erzählte ihm seine Mutti:
    Es war einmal ein kleiner Bär... der wollte eine Geschichte hörn... Da erzählte ihm seine Mutti:
    Es war einmal ein kleiner Bär... der wollte eine Geschichte hörn... Da erzählte ihm seine Mutti:
    ... Nun solltest es selber wissen. :'D

    Dieser Beitrag wurde bereits 5 mal editiert, zuletzt von „MemoAnMichSelbst“ ()

    MemoAnMichSelbst schrieb:

    Eine andere alternative wäre ja eine hinterlegte .txt Datei oder ähnliches, in welche der Wert steht und welche immer nur kurz ausgelesen wird. Dieser Wert wird dann um 1 hochgezählt in die txt zurückgeschrieben und ins Word-Formulat geschrieben.


    So würde ich es machen. Der Pfad sollte mit

    Visual Basic-Quellcode

    1. application.ActiveDocument.Path
    herauszufinden sein.
    Bei einer "globalen" Datei würde ich den Netzwerkpfad wohl aber direkt hinterlegen.

    Spoiler anzeigen

    Visual Basic-Quellcode

    1. Private Sub test()
    2. Dim Nummer As Long
    3. Nummer = NummerHolen
    4. If Nummer > 0 Then
    5. MsgBox Nummer, vbOKOnly + vbInformation
    6. Else
    7. MsgBox "Pfad nicht vorhanden", vbOKOnly + vbCritical
    8. End If
    9. End Sub
    11. Private Function NummerHolen() As Long
    12. Dim pfad As String
    13. Dim f As Integer
    14. Dim s As String
    16. pfad = Application.ActiveDocument.Path
    17. If pfad = "" Then pfad = "g:\Vorlagen"
    18. If FileExists(pfad & "\", True) Then
    19. Dateiname = pfad & "\fortlaufendenummer.txt"
    20. f = FreeFile
    21. If FileExists(Dateiname) Then
    22. Open Dateiname For Input As #f
    23. Line Input #f, s
    24. If IsNumeric(s) Then
    25. NummerHolen = CLng(s)
    26. End If
    27. Close #f
    28. NummerHolen = NummerHolen + 1
    29. Else
    30. NummerHolen = 1
    31. End If
    32. Open Dateiname For Output As #f
    33. Print #f, Str(NummerHolen)
    34. Close #f
    35. Else
    36. NummerHolen = 0
    37. End If
    39. End Function
    41. Private Function FileExists(ByVal Dateiname, Optional Ordner As Boolean = False) As Boolean
    42. If Ordner Then
    43. If Dir(Dateiname, vbDirectory) <> "" Then
    44. FileExists = True
    45. End If
    46. Else
    47. If Dir(Dateiname) <> "" Then
    48. FileExists = True
    49. End If
    51. End If
    53. End Function
    Gruß
    Peterfido

    Keine Unterstützung per PN!

    Dieser Beitrag wurde bereits 3 mal editiert, zuletzt von „peterfido“ ()

    Aloa und herzlichen Dank. Das klappt soweit. Er zählt hoch usw.

    ABER ^^ ein kleines Problem habe ich noch.
    Ich starte die Routine beim AutoOpen... Habe diese in der .dot hinterlegt. Nur leider führt er diese nicht aus, wenn jemand die Vorlage via Doppelklick startet... Sondern nur, wenn man diese explizit über Word öffnet.

    Ich denke es hat wieder etwas damit zutun, dass er direkt eine Dokument1.doc aus der .dot macht, sobald ich diese mittels Doppelklick starte.

    Kann ich irgendwie das Makro von der Vorlage an die zu .doc Datei übergeben?
    Es war einmal ein kleiner Bär... der wollte eine Geschichte hörn... Da erzählte ihm seine Mutti:
    Es war einmal ein kleiner Bär... der wollte eine Geschichte hörn... Da erzählte ihm seine Mutti:
    Es war einmal ein kleiner Bär... der wollte eine Geschichte hörn... Da erzählte ihm seine Mutti:
    ... Nun solltest es selber wissen. :'D

    Visual Basic-Quellcode

    1. Option Explicit
    3. Sub AutoNew()
    4. On Error Resume Next
    5. ReplaceBookmarkText ActiveDocument, "counter", CStr(NummerHolen)
    6. End Sub
    8. Sub ReplaceBookmarkText(oDoc As Document, strBMName As String, strBMText As String)
    9. Dim rng As Range
    10. If oDoc.Bookmarks.Exists(strBMName) Then
    11. Set rng = oDoc.Bookmarks(strBMName).Range
    12. rng.Text = strBMText
    13. oDoc.Bookmarks.Add strBMName, rng
    14. Set rng = Nothing
    15. End If
    16. End Sub
    18. Private Function NummerHolen() As Long
    19. Dim pfad As String
    20. Dim f As Integer
    21. Dim s As String
    22. Dim Dateiname As String
    23. pfad = Application.ActiveDocument.Path
    24. If pfad = "" Then pfad = "C:\Users\memoanmichselbst\Desktop"
    25. Dateiname = pfad & "\Wert.txt"
    26. f = FreeFile
    27. If FileExists(Dateiname) Then
    28. Open Dateiname For Input As #f
    29. Line Input #f, s
    30. If IsNumeric(s) Then
    31. NummerHolen = CLng(s)
    32. End If
    33. Close #f
    34. NummerHolen = NummerHolen + 1
    35. Else
    36. NummerHolen = 1
    37. End If
    38. Open Dateiname For Output As #f
    39. Print #f, Str(NummerHolen)
    40. Close #f
    42. End Function
    44. Private Function FileExists(ByVal Dateiname) As Boolean
    45. If Dir(Dateiname) <> "" Then
    46. FileExists = True
    47. End If
    48. End Function


    So tuts :D
    Vielen lieben Dank.
    Es war einmal ein kleiner Bär... der wollte eine Geschichte hörn... Da erzählte ihm seine Mutti:
    Es war einmal ein kleiner Bär... der wollte eine Geschichte hörn... Da erzählte ihm seine Mutti:
    Es war einmal ein kleiner Bär... der wollte eine Geschichte hörn... Da erzählte ihm seine Mutti:
    ... Nun solltest es selber wissen. :'D

    Ein kleines Anliegen habe ich dochnoch.
    pfad = Application.ActiveDocument.Path
    scheint nicht so recht zu funktionieren.
    Er zieht sich immer den fix hinterlegten Pfad aus
    If pfad = "" Then pfad = "C:\Users\memoanmichselbst\Desktop"
    Was natürlich doof ist, da man so das Dokument nicht einfach kopieren kann.
    Es war einmal ein kleiner Bär... der wollte eine Geschichte hörn... Da erzählte ihm seine Mutti:
    Es war einmal ein kleiner Bär... der wollte eine Geschichte hörn... Da erzählte ihm seine Mutti:
    Es war einmal ein kleiner Bär... der wollte eine Geschichte hörn... Da erzählte ihm seine Mutti:
    ... Nun solltest es selber wissen. :'D

    Wenn Du eine neue Datei erstellst, dann hat diese noch keinen Pfad. Erst nach dem ersten Speichern ist ein Pfad vorhanden. Deswegen auch meine Abfrage auf einen gültigen Pfad.
    Gruß
    Peterfido

    Keine Unterstützung per PN!

    Beim Drucken um eins erhöhen

    Hallo

    Ich habe ein ähnliches Problem und finde keine Lösung.

    Mein Dokument muss nicht beim öffnen um eins erhöht werden, sondern beim drucken.

    Man gibt also die Anzahl der Drucke in Word 2010 bei den Druckeinstellungen an und das Dokument wird dann immer mit der jeweiligen Nummer des aktuellen Druckes versehen.

    Kann man so etwas auch machen?
    In einem anderen Forum gabs noch keine passende Lösung und hoffe auf dieses hier.

    Gruß von der Nordsee

    Matthias





    EDIT:

    ERLEDIGT!

    Habe etwas cooles gefunden. Man muss einfach mal die Suche bei Google mit anderen Begriffen füttern! :P

    Hier mal der Link:

    web.archive.org/web/2007082305…obst/WordFAQ/Kollerat.htm

    Ich hoffe, dass der noch lange bleibt! Echt Super und funktioniert sehr gut.

    Dieser Beitrag wurde bereits 1 mal editiert, zuletzt von „Webbi76“ ()

    Hey,

    Webbi76 schrieb:

    ERLEDIGT!

    freut mich, dass du dein Problem noch lösen konntest. Allerdings solltest du bei künftigen Problemen darauf achten, keine Themen zu "missbrauchen", die schon seit gut 1 1/2 Jahren erledigt sind. Eröffne in solchen Fällen einfach ein neues Thema (und verweise ggfs. auf ähnliche Themen/Problemstellungen).

    --> Thema geschlossen

    Gruß (und noch viel Spaß im Forum) Manschula

Facebook
Telefonspende