Hallo Marcus,
ich würde einfach Pfad und Backcolor in eine .ini-Datei schreiben:

Option Explicit
Option Compare Text
Declare Function WritePrivateProfileString Lib "kernel32" Alias "WritePrivateProfileStringA" _
(ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpString As Any, _
ByVal lpFileName As String) As Long
Declare Function GetPrivateProfileString Lib "kernel32" Alias "GetPrivateProfileStringA" _
(ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpDefault As String, _
ByVal lpReturnedString As String, ByVal nSize As Long, ByVal lpFileName As String) As Long

Public Function GetIni(ByVal Name As String, ByVal Abschnitt As String, _
ByVal Schlüssel As String, ByVal Default As String) As String

Dim Buffer As String * 255
Dim Size As Long
Dim longX As Long
Dim Speicherpfad As String
On Error GoTo err
Speicherpfad = App.Path & "\" & Name & ".ini"
Size = GetPrivateProfileString(Abschnitt, Schlüssel, Default, Buffer, _
Len(Buffer), Speicherpfad)
GetIni = Left(Buffer, Size)

Rem Fehler
Exit Function
err:
MsgBox err.Description
Exit Function
End Function


Public Sub PutIni(ByVal Name As String, ByVal Abschnitt As String, _
ByVal Schlüssel As String, ByVal Wert As String)
On Error GoTo err
Dim longX As Long
Dim Speicherpfad As String
Speicherpfad = App.Path & "\" & Name & ".ini"

longX = WritePrivateProfileString(Abschnitt, Schlüssel, Wert, _
Speicherpfad)

Rem Fehler
Exit Sub
err:
MsgBox err.Description
Exit Sub
End Sub


zum speichern also:
Call PutIni("rtf-dateien", "Beispiel.rtf", "hgfarbe", RichTextBox1.Backcolor)

und zum einlesen:
GetIni("rtf-dateien", "Beispiel.rtf", "hgfarbe", vbblack)

Ich bin davon ausgegangen, dass Du weisst wo die Datei gespeichert ist. Wenn nicht, dann gehts natürlich auch nicht so.

Du könntest die Farbe in der INI Datei speichern, und beim laden der rtf-datei die Farbe wieder aus der INI Datei laden.