Code anpassen: WLAN-Verbindung deaktivieren/aktivieren

  • VBScript

Es gibt 14 Antworten in diesem Thema. Der letzte Beitrag () ist von petaod.

    Code anpassen: WLAN-Verbindung deaktivieren/aktivieren

    Hallo,

    ich habe folgenden Code gefunden und angepasst, der die Netzwerk-Verbindung "WiFi" je nach Status aktiviert/deaktiviert. Ich bekomme den Code leider nicht so geändert, dass das Script grundsätzlich die Netzwerk-Verbindung "WiFi" deaktiviert und wieder aktiviert. Die Toggle-Funktion möchte ich nicht. Kann mir jemand helfen?

    Vielen Dank.

    Gruß
    frankieman

    Visual Basic-Quellcode

    1. '~ Toggle a SPECIFIED NIC on or off
    2. Option Explicit
    4. Const NETWORK_CONNECTIONS = &H31&
    6. Dim objShell, objFolder, objFolderItem, objEnable, objDisable
    7. Dim folder_Object, target_NIC
    8. Dim NIC, clsVerb
    9. Dim str_NIC_Name, strEnable, strDisable
    10. Dim bEnabled, bDisabled
    12. ' ========================================================
    13. ' ===== place the name of your network adapter here ======
    14. ' examples:
    15. ' str_NIC_Name = "Local Area Connection 2"
    16. ' str_NIC_Name = "Wireless Connection 1"
    17. ' ========================================================
    18. str_NIC_Name = "wifi"
    19. ' ========================================================
    21. 'strEnable = "En&able"
    22. 'strDisable = "Disa&ble"
    23. strEnable = "&Aktivieren"
    24. strDisable = "&Deaktivieren"
    26. ' create objects and get items
    27. Set objShell = CreateObject("Shell.Application")
    28. Set objFolder = objShell.Namespace(NETWORK_CONNECTIONS)
    29. Set objFolderItem = objFolder.Self
    30. Set folder_Object = objFolderItem.GetFolder
    32. ' see if the namespace exists
    33. If folder_Object Is Nothing Then
    34. Wscript.Echo "Could not find Network Connections"
    35. WScript.Quit
    36. End If
    38. Set target_NIC = Nothing
    40. ' look at each NIC and match to the chosen name
    41. For Each NIC In folder_Object.Items
    42. If LCase(NIC.Name) = LCase(str_NIC_Name) Then
    43. ' proper NIC is found, get it
    44. Set target_NIC = NIC
    45. End If
    46. Next
    48. If target_NIC Is Nothing Then
    49. WScript.Echo "Unable to locate proper NIC"
    50. WScript.Quit
    51. End If
    53. Set objEnable = Nothing
    54. Set objDisable = Nothing
    55. bEnabled = True
    56. For Each clsVerb In target_NIC.Verbs
    57. '~ Wscript.Echo clsVerb
    58. If clsVerb.Name = strEnable Then
    59. Set objEnable = clsVerb
    60. bEnabled = False
    61. End If
    62. If clsVerb.Name = strDisable Then
    63. Set objDisable = clsVerb
    64. End If
    65. Next
    67. If bEnabled Then
    68. objDisable.DoIt
    69. Else
    70. objEnable.DoIt
    71. End If
    73. '~ Give the connection time to stop/start
    74. WScript.Sleep 1000
    75. WScript.Quit

    Dieser Beitrag wurde bereits 1 mal editiert, zuletzt von „frankieman“ ()

    Danke, dass du mir helfen willst. Aber das kann nicht funktionieren. Ich möchte mit dem Code:

    1. Die Netzwerkverbindung aktivieren, wenn die Verbindung deaktiviert ist und
    2. die Netzwerkverbindung deaktivieren und wieder aktivieren, wenn sie aktiviert ist.

    Gruß
    frankieman

    Es hilft doch enorm, wenn du deine Wünsche richtig formulierst.

    Visual Basic-Quellcode

    1. If bEnabled Then objDisable.DoIt
    2. WScript.Sleep 1000
    3. objEnable.DoIt
    Aber mit ein klein wenig Nachdenken hättest du womöglich selbst drauf kommen können. ;)
    --
    If Not Program.isWorking Then Code.Debug Else Code.DoNotTouch
    --

    Das Löschen der Zeilen bringt nicht das gewünschte Ergebnis und ich komme trotz kommentierter Zeilen nicht darauf, was geändert werden muss. Ich bin kein Coder und kann nur ein bißchen VBA. Mehr nicht. Ich habe auch keine Entwicklungsumgebung für VBS installiert und will es auch nicht. Ich wollte lediglich einen kleinen Code angepasst haben, den man in anderen VBA-Foren funktionierend bekommt, wenn höflich nachgefragt wird und keine ungetesteten Code-Schnipsel. Momentan habe ich das Gefühl gegen die Wand zu laufen. Vielleicht verlange ich aber auch zu viel oder bin verkehrt davor ...

    Gruß
    frankieman

    frankieman schrieb:

    Ich wollte lediglich einen kleinen Code angepasst haben, den man in anderen VBA-Foren funktionierend bekommt
    C&P ist halt nur dann sinnvoll, wenn man versteht, was man kopiert.
    Im Übrigen ist der Code VBS und nicht VBA, weshalb ihn dir vielleicht dort keiner angepasst hat.

    Ich habe auch keine Entwicklungsumgebung für VBS installiert und will es auch nicht.
    Interessant. Statt dessen spielst du jetzt hier den Beleidigten.
    Tipp: Mit einer VBA-Entwicklungsumgebung kann man mit Minimalanpassungen auch VBS debuggen.


    Nicht deinetwegen, sondern weil mich das Thema gereizt hat und den Spagetti-Code nicht sehen konnte, habe ich das Ganze mal etwas strukturiert:
    Spoiler anzeigen

    Visual Basic-Quellcode

    1. Option Explicit
    2. Const EnableVerb = "&Aktivieren"
    3. Const DisableVerb = "&Deaktivieren"
    4. Dim NIC
    6. Set NIC = Adapter("Wireless Network Connection 2")
    7. If NIC Is Nothing Then ErrorExit "NIC not found"
    8. 'Toggle NIC
    9. DisableEnable NIC
    11. Sub Toggle(NIC)
    12. If IsEnabled(NIC) Then Disable NIC Else Enable NIC
    13. End Sub
    15. Sub DisableEnable(NIC)
    16. Disable NIC
    17. Enable NIC
    18. End Sub
    20. Sub Disable(NIC)
    21. ExecuteAction NIC, DisableVerb
    22. End Sub
    24. Sub Enable(NIC)
    25. ExecuteAction NIC, EnableVerb
    26. End Sub
    28. Sub ExecuteAction(NIC, Action)
    29. Dim Verb
    30. For Each Verb In NIC.Verbs
    31. If Verb.Name = Action Then
    32. Verb.DoIt
    33. WScript.Sleep 1000
    34. Exit For
    35. End If
    36. Next
    37. End Sub
    39. Function IsEnabled(NIC)
    40. Dim Verb
    41. For Each Verb In NIC.Verbs
    42. If Verb.Name = EnableVerb Then Exit For
    43. If Verb.Name = DisableVerb Then
    44. IsEnabled = True
    45. Exit For
    46. End If
    47. Next
    48. End Function
    50. Function Adapter(Name)
    51. Const NETWORK_CONNECTIONS = &H31&
    52. Dim Shell, Connections, FolderItem, Folder
    53. Set Shell = CreateObject("Shell.Application")
    54. Set Connections = Shell.Namespace(NETWORK_CONNECTIONS)
    55. Set FolderItem = Connections.Self
    56. Set Folder = FolderItem.GetFolder
    57. For Each Adapter In Folder.Items
    58. If LCase(Adapter.Name) = LCase(Name) Then Exit Function
    59. Next
    60. Set Adapter = Nothing
    61. End Function
    63. Sub ErrorExit(Message)
    64. MsgBox Message
    65. WScript.Quit
    66. End Sub
    --
    If Not Program.isWorking Then Code.Debug Else Code.DoNotTouch
    --

    Dieser Beitrag wurde bereits 1 mal editiert, zuletzt von „petaod“ ()

    Ich will das Thema nicht unnötig anheizen. Nur so viel: Mit deinen Kommentaren und Annahmen auf meine Zitate liegst du verkehrt oder hast mein Geschriebenes nicht verstanden. Back to topic.

    Danke, dass du mir helfen willst. Wenn ich das Script nun ausführe, bleibt es bei der Togglefunktion. Mit anderen Worten: Ist der Netzwerkadapter aktiviert, so wird er deaktiviert und nicht wieder aktiviert. Ich habe den QT mal in VBA importiert, durch den Debugger im Einzelschritt gejagt und festgestellt, das beim Reaktivieren der NIC Verb.Name <> Action ist, weshalb die Aktiverung nicht erfolgt.

    Visual Basic-Quellcode

    1. For Each Verb In NIC.Verbs
    2. If Verb.Name = Action Then 'wird nicht ausgeführt, da Verb.Name ="&Deaktivieren" ist und Action = "&Aktivieren"
    3. Verb.DoIt
    4. 'WScript.Sleep 1000
    5. Exit For
    6. End If
    7. Next


    Und bei dir läuft das?

    Gruß
    frankieman

    Also bei mir geht Alles Einwandfrei ?

    Aktiv -- Deaktiv !!!

    Anhang ;)

    Natürlich sollte man den Wlan -Adapter benennen ;)



    Dateien
    :D Ein Programm sollte nicht nur Hand und Fuß, sondern auch Herz und Hirn haben. (Michael Anton) :D

    MFG Jörg ;)

    Muss jeder vermeintliche Programmierer ne Signatur haben ??

    Der "Gag" soll sein, mit einem Klick deaktivieren und wieder aktivieren zu können. Und das läuft mit dem Script bei mir einfach nicht. Es geht nur:
    Wenn aktiviert, dann deaktivieren
    Wenn deaktiviert, dann aktivieren

    Hintergund ist folgender: Mein Notebook hat eine neue Netzwerkkarte erhalten, das die Verbindung zum Router nicht immer herstellen kann, obwohl die Netzwerkkarte aktiviert ist. Ich möchte mit dem Script die Karte mit einem Klick durch Deaktivieren und Aktivierung zur Verbindungsherstellung bringen.

    Ich habe Windows 8.1. Liegt es vielleicht daran?

    Gruß
    frankieman

    frankieman schrieb:

    Der "Gag" soll sein, mit einem Klick deaktivieren und wieder aktivieren zu können.
    Der "Gag" an dem Script ist das Sleep.
    Das soll Warten bis das das Verb entsprechend umgeschaltet hat.
    Wenn du das auskommentierst geht natürlich nichts.
    Wenn das bei dir trotz Sleep nicht funktioniert, ist dein Rechner zu langsam und du musst den Timeout erhöhen.

    Oder du machst es gleich richtig und loopst in einer Schleife, bis der Adapter den Status (und damit das Verb) umgeschaltet hat.
    Aber dann bitte zusätzlichen Schleifenabbruch mit einbringen, um Endlosschleifen zu vermeiden.

    frankieman schrieb:

    Ich habe Windows 8.1. Liegt es vielleicht daran?
    Kann auch sein.
    Um Windows 8 mache ich in den Fällen, wo ich's vermeiden kann, momentan noch einen großen Bogen.

    frankieman schrieb:

    Mein Notebook hat eine neue Netzwerkkarte erhalten, das die Verbindung zum Router nicht immer herstellen kann, obwohl die Netzwerkkarte aktiviert ist
    Das wäre für mich eher ein pausibler Grund, dass mit dem Treiber irgendwas nicht stimmt und der Aktiviervorgang zu lange benötigt.
    Ein Grund mehr, den Sleep-Timeout zu erhöhen.
    --
    If Not Program.isWorking Then Code.Debug Else Code.DoNotTouch
    --

    Das Sleep ist auskommentiert, weil ich den Code in VBA im Einzelschritt getestet habe, steht auch im Post 10. Die Erhöhung des Sleeps hilft leider nicht.

    Wenn auf deinem Rechner der Code die NIC deaktiviert und wieder aktiviert, bzw. nur aktiviert und bei mir nicht, kann es nur an Hardware, Treiber oder BS liegen. Ein Gerücht besagt, dass gerade Windows-Versionen schlecht sind. Vielleicht wird es wieder was mit Windows 9.

    Danke und Gruß
    frankieman

    frankieman schrieb:

    Und das läuft mit dem Script bei mir einfach nicht
    Wenn der Toggle geht, muss mit langem Timeout auch DisableEnable funktionieren.

    Ich würde mir mal den neuesten Treiber für die Karte besorgen.
    Zum einen vom Hersteller, zum anderen von Microsoft.
    --
    If Not Program.isWorking Then Code.Debug Else Code.DoNotTouch
    --

Facebook