Speicher zwischen Applikationen Teilen

    • VB6

      Speicher zwischen Applikationen Teilen

      Die nachfolgende Klasse dient zum vereinfachen des
      Datenaustausches zwischen zwei selbst programmierten
      Applikationen:

      Visual Basic-Quellcode

      1. Option Explicit
      3. Private Declare Function CreateFileMapping Lib "kernel32.dll" Alias _
      4. "CreateFileMappingA" (ByVal hFile As Long, _
      5. ByVal lpFileMappigAttributes As Long, _
      6. ByVal flProtect As Long, _
      7. ByVal dwMaximumSizeHigh As Long, _
      8. ByVal dwMaximumSizeLow As Long, _
      9. ByVal lpName As String) As Long
      11. Private Declare Function MapViewOfFile Lib "kernel32.dll" (ByVal hFileMappingObject As Long, _
      12. ByVal dwDesiredAccess As Long, _
      13. ByVal dwFileOffsetHigh As Long, _
      14. ByVal dwFileOffsetLow As Long, _
      15. ByVal dwNumberOfBytesToMap As Long) As Long
      17. Private Declare Function UnmapViewOfFile Lib "kernel32.dll" (ByVal lpBaseAddress As Long) As Long
      18. Private Declare Function CloseHandle Lib "kernel32.dll" (ByVal hObject As Long) As Long
      20. Private Declare Function CopyMemory Lib "kernel32.dll" Alias "RtlMoveMemory" (ByRef Destination As Any, ByRef Source As Any, ByVal Length As Long) As Long
      21. Private Declare Function ZeroMemory Lib "kernel32.dll" Alias "RtlZeroMemory" (ByRef Destination As Any, ByVal Length As Long) As Long
      22. Private Declare Function lstrlen Lib "kernel32.dll" Alias "lstrlenA" (ByVal lpString As Long) As Long
      24. Private m_hMapObject As Long
      25. Private m_lpMemory As Long
      26. Private m_strMemName As String
      27. Private m_lngBytes As Long
      29. Function Initialize(ByVal strMemName As String, ByVal lngBytes As Long) As Boolean
      30. Uninitialize
      32. m_hMapObject = CreateFileMapping(&HFFFFFFFF, 0, &H4, 0, lngBytes, strMemName)
      34. If m_hMapObject <> 0 Then
      35. m_lpMemory = MapViewOfFile(m_hMapObject, &H2, 0, 0, 0)
      36. m_strMemName = strMemName
      37. m_lngBytes = lngBytes
      38. ZeroMemory ByVal m_lpMemory, m_lngBytes
      39. End If
      40. End Function
      42. Function GetMemory(Optional ByVal strMemName As String, Optional ByVal lngBytes As Long) As String
      43. Dim strMemory As String
      45. If Len(strMemName) > 0 And strMemName <> m_strMemName Then
      46. m_hMapObject = CreateFileMapping(&HFFFFFFFF, 0, &H4, 0, lngBytes, strMemName)
      48. If m_hMapObject <> 0 And Err.LastDllError = 183 Then 'Err 183 = File Already Exists
      49. m_lpMemory = MapViewOfFile(m_hMapObject, &H2, 0, 0, lngBytes)
      50. strMemory = String$(lstrlen(m_lpMemory), Chr$(0))
      51. CopyMemory ByVal strMemory, ByVal m_lpMemory, Len(strMemory)
      52. End If
      53. Else
      54. strMemory = String$(lstrlen(m_lpMemory), Chr$(0))
      55. CopyMemory ByVal strMemory, ByVal m_lpMemory, Len(strMemory)
      56. End If
      58. GetMemory = strMemory
      59. End Function
      61. Sub SetMemory(ByVal strValue As String, Optional ByVal strMemName As String, Optional ByVal lngBytes As Long)
      62. strValue = strValue & Chr$(0)
      64. If m_lngBytes > 0 Then
      65. If Len(strValue) > m_lngBytes Then Exit Sub
      66. End If
      68. If Len(strMemName) > 0 And strMemName <> m_strMemName Then
      69. m_hMapObject = CreateFileMapping(&HFFFFFFFF, 0, &H4, 0, lngBytes, strMemName)
      71. If m_hMapObject <> 0 And Err.LastDllError = 183 Then 'Err 183 = File Already Exists
      72. m_lpMemory = MapViewOfFile(m_hMapObject, &H2, 0, 0, 0)
      73. CopyMemory ByVal m_lpMemory, ByVal strValue, Len(strValue)
      74. End If
      75. Else
      76. CopyMemory ByVal m_lpMemory, ByVal strValue, Len(strValue)
      77. End If
      78. End Sub
      80. Sub Uninitialize()
      81. If m_hMapObject <> 0 Then
      82. UnmapViewOfFile m_lpMemory
      83. CloseHandle m_hMapObject
      85. m_lpMemory = 0
      86. m_hMapObject = 0
      87. End If
      88. End Sub
      90. Private Sub Class_Terminate()
      91. Uninitialize
      92. End Sub


      Hier ein Beispiel zum benutzen der Klasse:

      Visual Basic-Quellcode

      1. 'Applikation 1:
      2. gMemory.Initialize "Datenaustausch", 1024 'Größe des gemeinsamen Speichers kann natürlich variieren
      4. 'Applikation 2:
      5. gMemory.SetMemory "Neue Daten", "Datenaustausch", 1024
      7. 'Applikation 1:
      8. If gMemory.GetMemory = "Neue Daten" Then '[...]



      Keywords: Visual Basic 6, VB 6, mehrere Programme, Speicher teilen, Variablen übergeben, Daten übergeben, Datenaustausch, Funktion, Function, SetMemory, GetMemory, API, CreateFileMapping, MapViewOfFile, CopyMemory, RTLMoveMemory

      Dieser Beitrag wurde bereits 2 mal editiert, zuletzt von „Lupus“ ()

    Facebook
    Telefonspende