Maus Cursor Egoshooter

Coldpepp · 24. Juli 2010, 21:11

Hallo ihr netten Forummitglieder!
Tut mir leid für die Noob Frage aber ich komme im Moment nicht weiter.
Ich und ein paar Freunde sind dabei ein 3D Egoshooter Game zu endwickeln.
Es soll ähnlich wie Wolfstein 3d werden!
Also kommen wir zu meiner Frage:
Info:
Programmiersprache = Visual Basic 6 & OPENGL
Problem = Cursor

Zur Zeit siht der Code zum Maus einfangen und position ermitteln & auswerten so aus:

Visual Basic-Quellcode

Option Explicit
Private Declare Function SetCursorPos Lib "user32" ( _
ByVal x As Long, _
ByVal y As Long) As Long
Private Declare Function GetCursorPos Lib "user32" ( _
lpPoint As POINTAPI) As Long
Private Type POINTAPI
x As Long
y As Long
End Type
Private MausPos As POINTAPI
Private Sub Form_Load()
SetCursorPos 750, 500
GetCursorPos MausPos
MsgBox "Zum Beenden drücken sie ESC!", vbOKOnly, "Info"
ShowCursor (0)
End Sub
Private Sub Form_Resize()
ReSizeGLScene ScaleWidth, ScaleHeight
End Sub
Private Sub Form_Terminate()
ShowCursor (1)
End
End Sub
Private Sub Form_Unload(Cancel As Integer)
ShowCursor (1)
End
End Sub
Private Sub Timer1_Timer()
'Interval = 1000
'Enabled = true
Private Sub TLenk_Timer()
'Interval = 1
'Enabled = true
Dim Temp As POINTAPI
GetCursorPos Temp
If Temp.x < MausPos.x Then
Kamera.DY = Kamera.DY + 1.5
MausPos.x = Temp.x
MausPos.y = Temp.y
End If
If Temp.x > MausPos.x Then
Kamera.DY = Kamera.DY - 1.5
MausPos.x = Temp.x
MausPos.y = Temp.y
End If
End Sub
SetCursorPos 750, 500
End Sub

aber durch diesen Code siht dan der point in der mitte so schrumpelig und schlampig aus
kann mir jemand bitte eine andere möglichkeit zeigen?
ich währe euch sehr dankbar

übrigens ned wundern ich habe bisher nur nach links und rechts drehen eingebaut und vor/zurück laufen den restlichen überflüssigen code habe ich weggelassen!

Neptun · 25. Juli 2010, 00:08

Hallo Coldpepp,
was sieht schrumpelig aus? Der Mauszeiger wird doch durch
ShowCursor(0) ausgeschaltet.
Übrigens:

Visual Basic-Quellcode

MausPos.x = Temp.x
MausPos.y = Temp.y

kann man ersetzen durch:

Visual Basic-Quellcode

MausPos = Temp

Eine Anwendung sollte nicht mit End beendet werden, sonst
bleiben Daten im Speicher. Siehe dazu:
activevb.de/rubriken/faq/faq0013.html

Coldpepp · 26. Juli 2010, 00:52

ohoo dankesehr schonmal!

also nicht den mauszeiger sondern zum beispiel wen ich nach links or rechts gehe mit der maus dan egal wie schnel ich die maus bewege die kamera bewegt sich immer im selben tempo!

hier der restliche code vielleicht sagt er dir ja mehr

Visual Basic-Quellcode

Private Declare Function GetObjectA Lib "gdi32" (ByVal hObject As Long, ByVal nCount As Long, ByRef lpObject As Any) As Long
Global PrgRun As Boolean 'Flag = Programm läuft
Public Texture(15) As GLuint 'Handle der Texturen
Private hrc As Long 'Handle für den OpenGL Gerätekontext
Private Type BITMAP
bmType As Long
bmWidth As Long
bmHeight As Long
bmWidthBytes As Long
bmPlanes As Integer
bmBitsPixel As Integer
bmBits As Long
End Type
Private Type TpVertex 'Vertex-Struktur
x As GLfloat 'X-Koordinate
y As GLfloat 'Y-Koordinate
Z As GLfloat 'Z-Koordinate
U As GLfloat 'U-Koordinate (Textur)
V As GLfloat 'V-Koordinate (Textur)
End Type
Private Type TpTriangle 'Dreieck-Struktur
Vertex(2) As TpVertex 'Array mit 3 Punkten
T As Integer 'Index der verwendeten Textur
End Type
Private Type TpSector 'Sektor-Struktur
Sct_NummTriangle As Integer 'Anzahl der Dreiecke im Sektor
Triangle() As TpTriangle 'Zeiger auf ein Array mit Dreiecken
End Type
Private Sektor(0) As TpSector 'Array für einen Sektor
Public Const PiToRad As Double = 0.0174532925 'Umrechnungsfaktor Grad => Radiant
Private Type TpKamera
x As GLfloat 'X-Position
y As GLfloat 'Y-Position
Z As GLfloat 'Z-Position
DY As GLfloat 'Drehwinkel um Y-Achse
End Type
Public Kamera As TpKamera
Public Sub LoadTexture(ByVal Filename As String, ByVal Index As Long)
Dim bmp As BITMAP
'Vorraussetzungen:
'Die Grafik muß quadratisch sein!
'Die Seitenlänge der Grafiken müssen 2er Potenzen entsprechen:
'16,32,64,128,256,512,1024 Pixel etc.
'Durch den Umweg über die Picturebox sind aber auch Formate wie jpg oder gif möglich.
'Die Autosize-Eigenschaft der Picturebox muß auf True stehen!
Form1.Picture1.Picture = LoadPicture(Filename) 'Bild laden
'GetObjectA gibt Informationen über die im Aufruf übermittelte Bitmap der
'Picturebox zurück und speichert diese in der bmp-Struktur.
'Es wird also eine Bitmap aus den Daten der Picturebox im Speicher erstellt.
If GetObjectA(Form1.Picture1.Picture.Handle, LenB(bmp), bmp) Then
glGenTextures 1, Texture(Index) 'kreiert eine Textur
glBindTexture glTexture2D, Texture(Index) 'Zuweisung: die Textur ist 2D
'Generieren der eigentlichen Texture in OpenGL
glTexImage2D glTexture2D, 0, 3, bmp.bmWidth, bmp.bmHeight, 0, tiBGRExt, GL_UNSIGNED_BYTE, ByVal bmp.bmBits
'Der 1. Parameter besagt wieder 2D Textur
'Der 2. Parameter gibt den Grad der Details an, ist aber vorerst einmal unwichtig
'Der 3. Parameter gibt die Art der Farbkanäle an, 3 = RGB.
'Parameter 4 und 5 sind Breite und Höhe der Textur
'Der 6. Parameter gibt die Rahmenbreite an, vorerst aber mal 0.
'Parameter 7 und 8 geben Farbformat (RGB) und Art der Daten (Unsigned Byte = 0 - 255) an.
'Der letzte Parameter übergibt schlußendlich die eigentliche Textur.
'Diese Zeilen legen fest, welcher Filter verwendet werden soll:
glTexParameteri glTexture2D, tpnTextureMinFilter, GL_LINEAR
glTexParameteri glTexture2D, tpnTextureMagFilter, GL_LINEAR
'tpnTextureMinFilter besagt, mit welchem Filter die Grafik zusammengedrückt werden soll.
'tpnTextureMagFilter besagt, mit welchem Filter die Grafik auseinandergezogen wird.
'Der Parameter GL_LINEAR erzeugt das beste Ergebnis, belastet aber den Prozessor.
'Möglich wäre auch GL_NEAREST. Das entlastet zwar die Hardware, sieht aber schnell recht pixelig aus.
LoadTexturePic = True
End If
End Sub
Public Sub Main()
Dim I As Integer, J As Integer 'Zählvariablen
Dim frm As Form
PrgRun = True 'Flag = das Programm läuft
Set frm = New Form1 'Fenster für OpenGL-Ausgabe
frm.ScaleMode = vbPixels 'das Fenster muß zwingend in Pixel bemessen werden
If CreateGLWindow(frm, 640, 480, 16) Then 'Fenster initialisieren
LoadWorld App.Path & "\World.txt" 'einlesen der Welt-Daten
Do 'Endlosschleife in der das Fenster laufend gelöscht und neu aufgebaut wird.
'Die Laufzeit dieser Schleife ist ausschlaggebend, wieviele Objekt gezeichnet werden können
glClear clrColorBufferBit Or clrDepthBufferBit ' löscht das Fenster und den Tiefenpuffer
glLoadIdentity 'setzt die aktuelle Modell-Matrix zurück
Kamera.y = Kamera.y 'wir bewegen uns nicht auf/ab und fixieren daher Y
glRotatef 360 - Kamera.DY, 0, 1, 0 'Welt in entgegengesetzter Richtung der Kamera drehen
glTranslatef Kamera.x, Kamera.y, Kamera.Z 'Welt verschieben
'Darstellung der eingelesenen Daten in einer Schleife
For I = 0 To Sektor(0).Sct_NummTriangle - 1 'alle Dreiecke abarbeiten
'Auswahl der gewünschten Textur
glBindTexture GL_TEXTURE_2D, Texture(Sektor(0).Triangle(I).T)
glBegin bmTriangles
For J = 0 To 2 '3 Punkte je Dreieck
With Sektor(0).Triangle(I).Vertex(J)
glTexCoord2f .U, .V: glVertex3f .x, .y, .Z
End With
Next
glEnd
Next
SwapBuffers (frm.hDC) 'Puffer tauschen (Double Buffering)
DoEvents
Loop While PrgRun 'Programm nur beenden, wenn PrgRun = False
'PrgRun ist Global definiert und wird im KeyDown-Ereignis von Form1 bei drücken von Escape gesetzt.
'alles freigeben und Programm beenden
If hrc <> 0 Then 'hatten wir einen Gerätekontext für OpenGL?
wglMakeCurrent 0, 0 'Freigeben des Gerätekontexts
wglDeleteContext (hrc) 'Freigeben des Renderingkontexts
End If
Unload frm
Set frm = Nothing
End
End If
End Sub
Public Function CreateGLWindow(frm As Form, Width As Integer, Height As Integer, Bits As Integer) As Boolean
Dim Mt_Diffuse(3) As GLfloat 'Material für diffuses Licht
Dim Mt_Ambient(3) As GLfloat 'Material für Umgebungslicht
Dim Mt_Specular(3) As GLfloat 'Material für gespiegeltes Licht
Dim Mt_Shiness(0) As GLfloat 'Glanz des Materials
Dim Lt_Position(3) As GLfloat 'Position der Lichtquelle
Dim Lt_Diffuse(3) As GLfloat 'diffuses Licht
Dim Lt_Ambient(3) As GLfloat 'Umgebungslicht
Dim Lt_Specular(3) As GLfloat 'Spotlicht / Glanzlicht
'Position der Lichtquelle
'auf der Z-Achse als positiver Wert = 10 Einheiten vor dem Bildschirm
Lt_Position(0) = 0#: Lt_Position(1) = 0#: Lt_Position(2) = 0#: Lt_Position(3) = 1#
'Materialeigenschaft für diffuses Licht
Mt_Diffuse(0) = 0.8: Mt_Diffuse(1) = 0.8: Mt_Diffuse(2) = 0.8: Mt_Diffuse(3) = 1#
'Materialeigenschaft für Umgebungslicht
Mt_Ambient(0) = 0.3: Mt_Ambient(1) = 0.3: Mt_Ambient(2) = 0.3: Mt_Ambient(3) = 1#
'Materialeigenschaft für Glanz
Mt_Specular(0) = 1: Mt_Specular(1) = 1: Mt_Specular(2) = 1: Mt_Specular(3) = 1
'Exponent für Glanz
Mt_Shiness(0) = 50#
'Lichtstärke/farbe für Umgebungslicht
Lt_Ambient(0) = 0.2: Lt_Ambient(1) = 0.2: Lt_Ambient(2) = 0.2: Lt_Ambient(3) = 1#
'Lichtstärke/farbe für diffuses Licht
Lt_Diffuse(0) = 0.5: Lt_Diffuse(1) = 0.5: Lt_Diffuse(2) = 0.5: Lt_Diffuse(3) = 0.5
'Lichtstärke/farbe für Spot (Glanz)
Lt_Specular(0) = 1: Lt_Specular(1) = 1: Lt_Specular(2) = 1: Lt_Specular(3) = 1
Dim pfd As PIXELFORMATDESCRIPTOR ' pfd erklärt Windows, wie das Fenster beschaffen sein soll
Dim PixelFormat As GLuint ' enthält das Ergebnis vom Versuch, ein Fenster mit den gegebenen Parametern zu erstellen
pfd.cColorBits = Bits 'Farbtiefe
pfd.cDepthBits = 16 '16 Bit Tiefenpuffer
'Der Tiefenpuffer enthält die Entfernung eines Pixels zur Kamera (Betrachter).
'Er verhindert, daß Objekte im Hintergrund beim Zeichnen Objekte im Vordergund überlagern.
pfd.dwFlags = PFD_DRAW_TO_WINDOW Or PFD_SUPPORT_OPENGL Or PFD_DOUBLEBUFFER
'PFD_DRAW_TO_WINDOW = das Format muß als Fenster sichtbar sein können
'PFD_SUPPORT_OPENGL = das Format muß OpenGL unterstützen
'PFD_DOUBLEBUFFER = das Foramt muß Double Buffering unterstützen
pfd.iLayerType = PFD_MAIN_PLANE 'Die Hauptebene auf der gezeichnt wird.
pfd.iPixelType = PFD_TYPE_RGBA 'Pixel werden im RGBA Modus dargestellt.
'RGB ist mit VB identisch. Für A wird ein Alpha-Wert für die Transparenz übergeben
pfd.nSize = Len(pfd) 'Größe der Struktur sollte natürlich stimmen
pfd.nVersion = 1 'Versionsnummer
PixelFormat = ChoosePixelFormat(frm.hDC, pfd) 'Windows nach einem oben beschriebenen Pixelformat fragen
If PixelFormat <> 0 Then
'Windows hat ein entsprechendes Format gefunden
If SetPixelFormat(frm.hDC, PixelFormat, pfd) <> 0 Then
'Einrichten des Pixelformates war erfolgreich
hrc = wglCreateContext(frm.hDC)
If hrc <> 0 Then
'ein Rendering Kontext wurde erstellt
If wglMakeCurrent(frm.hDC, hrc) <> 0 Then
'Der Kontext wurde aktiviert
frm.Show 'Fenster anzeigen
Call LoadTexture(App.Path & "\mauer.jpg", 1) 'laden und erzeugen eines Textures
Call LoadTexture(App.Path & "\holz.jpg", 2) 'laden und erzeugen eines Textures
Call LoadTexture(App.Path & "\ziegel.jpg", 3) 'laden und erzeugen eines Textures
Call LoadTexture(App.Path & "\rot.jpg", 4)
Call LoadTexture(App.Path & "\gelb.jpg", 5)
Call LoadTexture(App.Path & "\schwarz.jpg", 6)
Call LoadTexture(App.Path & "\grün.jpg", 7)
glEnable glcTexture2D 'Einschalten des Texture Mappings
glShadeModel smSmooth 'schaltet schöne Farbübergange ein
glClearColor 0#, 0#, 0#, 0.5 'schwarzer Hintergrund
glClearDepth 1# 'Tiefenpuffer zurücksetzten (später mehr)
glEnable glcDepthTest 'Aktivierung des Tiefentests (später mehr)
glDepthFunc cfLEqual 'Typ des Tiefentests (später mehr)
glHint htPerspectiveCorrectionHint, hmNicest 'Art der Perspectivenansicht
'hmNicest = beste Ansicht / hmFastest = schnellste Darstellung
glMaterialfv GL_FRONT, GL_SPECULAR, Mt_Specular(0) 'Materialeigenschaft für Specular setzen
glMaterialfv GL_FRONT, GL_SHININESS, Mt_Shiness(0) 'Exponent für den Glanz
glMaterialfv GL_FRONT, GL_DIFFUSE, Mt_Diffuse(0) 'Materialeigenschaft für Diffus setzen
glMaterialfv GL_FRONT, GL_AMBIENT, Mt_Ambient(0) 'Materialeigenschaft für Ambient setzen
glLightfv GL_LIGHT1, GL_DIFFUSE, Lt_Diffuse(0) 'diffuses Licht setzen
glLightfv GL_LIGHT1, GL_AMBIENT, Lt_Ambient(0) 'Umgebungslicht setzen
glLightfv GL_LIGHT1, GL_SPECULAR, Lt_Specular(0) 'Glanzlicht setzen
glLightfv GL_LIGHT1, GL_POSITION, Lt_Position(0) 'Position der Lampe setzen
glEnable GL_LIGHTING 'Licht einschalten.
glEnable GL_LIGHT1 'Licht Nr. 1 einschalten.
glEnable GL_COLOR_MATERIAL 'Farben unter Textur aktivieren
CreateGLWindow = True
End If
End If
End If
End If
End Function
Public Sub ReSizeGLScene(ByVal Width As GLsizei, ByVal Height As GLsizei)
'Anpassen der Größe und Initialisierung des OpenGL-Fensters
If Height = 0 Then 'Die Fensterhöhe muß größer 0 sein
Height = 1 'sonst kommt es zu einem Division by Zero Fehler
End If
glViewport 0, 0, Width, Height 'leeren des aktuellen Viewports
glMatrixMode mmProjection 'Auswahl der Projektionsmatrix
glLoadIdentity 'setzt die aktuelle Modell-Matrix zurück
gluPerspective 45#, Width / Height, 0.1, 100# 'Berechnung des aktuellen Seitenverhältnisses des Fensters
glMatrixMode mmModelView 'Auswahl der Modelview Projektionsmatrix
glLoadIdentity 'setzt die aktuelle Modell-Matrix zurück
End Sub
Public Sub LoadWorld(File As String)
Dim I, J As Integer 'Zählvariablen
Dim F As Long 'Dateinummer
Dim Zeile As String 'Einzelzeile aus der Datei
Dim Segment() As String 'einzelne Anweisung / Koordinate in der Zeile
Dim AnzDreieck As Integer 'Anzahl der Dreiecke in der Datei
'Datei öffnen
F = FreeFile
Open File For Input Shared As #F
'1. Zeile lesen
Line Input #F, Zeile
Segment = Split(Zeile, " ") 'Space als Trennzeichen
'hier in der 1. Zeile die Anzahl der Dreiecke
If Segment(0) = "NUMTRIANGLES" Then
AnzDreieck = Val(Segment(1))
ReDim Sektor(0).Triangle(AnzDreieck) 'Speicher für Dreieck-Koordinaten
Sektor(0).Sct_NummTriangle = AnzDreieck 'Anzahl der Dreiecke ablegen
I = 0
J = 0
Do 'Alle Dreiecke einlesen
Line Input #F, Zeile 'Zeile lesen
Zeile = Trim(Zeile) 'führende Spaces abschneiden
'Leere Zeilen und Kommentare (beginnen mit /) ignorieren
If Len(Zeile) > 0 And Left(Zeile, 1) <> "/" Then
Do
Zeile = Replace(Zeile, " ", " ") 'entfernen mehrfacher Spaces
Loop Until InStr(1, Zeile, " ") = 0
If J < 3 Then
Segment = Split(Zeile, " ") 'in Punkte zerlegen
'Punkte für Dreieck und Texturen in Struktur speichern
Sektor(0).Triangle(I).Vertex(J).x = Val(Segment(0))
Sektor(0).Triangle(I).Vertex(J).y = Val(Segment(1))
Sektor(0).Triangle(I).Vertex(J).Z = Val(Segment(2))
Sektor(0).Triangle(I).Vertex(J).U = Val(Segment(3))
Sektor(0).Triangle(I).Vertex(J).V = Val(Segment(4))
J = J + 1
Else
Sektor(0).Triangle(I).T = Val(Trim(Zeile)) 'Texturindex merken
J = 0 'Punktezähler zurücksetzen
I = I + 1 'nächstes Dreieck
End If
End If
Loop Until I >= AnzDreieck
End If
End Sub

Ende des Modules

fals jemand jetzt mit dem kommentaren kommen will wie z.B. Ihhh den code hast du geklaut bla bla dan lasst es bitte sein ja ich hab ihn geklaut von so ein tutorial aber ich erweitere den nur ne eigene map hab ich dazu auch schon gemacht sogar mehrere

@Neptun

Zählt das mit dem speicher im ram auch für PrgRun = False oder nur für End?

Neptun · 26. Juli 2010, 04:40

Hallo Coldpepp,
der Code nimmt ja auch keinen Bezug auf die Geschwindigkeit
der Maus. Du musst im Timer-Event die Differenz zwischen
Temp.x und MausPos.x bilden und in Abhängigkeit von der Grösse
des Wertes mal mehr und mal weniger zu Kamera.DY addieren oder
davon subtrahieren.

Zählt das mit dem speicher im ram auch für PrgRun = False oder nur für End?

Ist mir nur von End bekannt.

Maus Cursor Egoshooter

Maus Cursor Egoshooter

Visual Basic-Quellcode

Visual Basic-Quellcode

Visual Basic-Quellcode

Visual Basic-Quellcode

Benutzer online 1

Ähnliche Themen

2 Benutzer haben hier geschrieben