Dateibesitzer ermitteln und diese Dateien dann löschen

  • VBScript

Es gibt 2 Antworten in diesem Thema. Der letzte Beitrag () ist von p41n.

    Dateibesitzer ermitteln und diese Dateien dann löschen

    Hallo Zusammen,

    Nun habe ich noch ein weiteres kleines Problem. Ich denke, das dürfte für euch kein Problem darstellen. Aber ich komme absolut nicht mehr weiter. ?(

    Es geht darum die Dateien eines Ordner nach Besitzern zu analysieren und sämtliche Dateien des ermittelten Besitzers zu löschen.
    Beispielsweise enthält ein Ordner mit 100 Dateien 10 Dateien des Besitzers MaxMustermann in der Domäne contoso.com.
    Diese 10 Dateien möchte ich löschen und die anderen Dateien sollen unberührt bleiben.

    Bisher habe ich folgenden Code geschrieben:

    Visual Basic-Quellcode

    1. DIM objDatei
    3. strOrdner = "D:\Test\"
    5. set shell = CreateObject("Shell.Application")
    7. ' auf Papierkorb zugreifen
    8. Set FSO = CreateObject("Scripting.FileSystemObject")
    9. Set objOrdner = FSO.GetFolder(strOrdner)
    10. set folder = shell.NameSpace(strOrdner)
    11. set folderitems = folder.items
    13. fmtid = "{9B174B34-40FF-11D2-A27E-00C04FC30871}"
    15. intZahl = 0
    17. If folderitems.Count > 0 then
    19. For Each folderitem in folderitems
    21. besitzer = (folderitem.ExtendedProperty(fmtid & ",4"))
    23. For Each objDatei in objOrdner.Files
    25. If besitzer = "MusterPC\musterma" Then
    27. objDatei.Delete
    28. list = list & folderitem.name & _
    29. ": Besitzer ist " & besitzer & vbCr
    30. intZahl = intZahl + 1
    32. End If
    34. Next
    36. Next
    38. End If
    40. If intZahl = "0" Then
    41. MsgBox "Es wurden keine Dateien gelöscht"
    42. Else
    43. MsgBox "Es wurden " & intZahl & " Dateien gelöscht" & vbCrLf _
    44. & "Gelöscht wurden:" & vbCrLf & list, vbInformation
    45. End If


    Das Problem hierbei ist, dass das Script mir sämtliche Dateien löscht. Auch die, die dem angegebenen Benutzer gar nicht gehören.
    Im Prinzip löscht er also sämtliche Dateien in dem Ordner, obwohl nur eine Datei dem angegeben Anwender gehört.

    Kann mir wer helfen?


    Viele Grüße
    p41n

    Erstmal Danke für den Tipp. Er hat mich auf die richtige Spur gebracht. :thumbup:
    Dennoch hat es etwas gedauert. Habs aber letztendlich hinbekommen.

    Und hier nun der Code für die, die ein ähnliches Problem haben sollten:


    Visual Basic-Quellcode

    1. 'InputBox als Abfrage, um den Besitzer zu erfragen, dessen Dateien gelöscht werden sollen
    2. Owner = InputBox("Bitte geben Sie den Besitzer ein, dessen Dateien gelöscht werden sollen:")
    4. 'Flags für den BrowsforFolder Dialog
    5. Const BIF_returnonlyfsdirs = &H0001
    6. Const BIF_dontgobelowdomain = &H0002
    7. Const BIF_statustext = &H0004
    8. Const BIF_returnfsancestors = &H0008
    9. Const BIF_editbox = &H0010
    10. Const BIF_validate = &H0020
    11. Const BIF_browseforcomputer = &H1000
    12. Const BIF_browseforprinter = &H2000
    13. Const BIF_browseincludefiles = &H4000
    15. 'Deklaration des FileSystemObject und der Shell.Applikation
    16. Set objDlg = WScript.CreateObject("Shell.Application")
    17. Set fso = CreateObject("Scripting.FileSystemObject")
    19. 'Ermitteln des Quellordners über die BrowseForFolder-Methode
    20. Set objStartFolder = objDlg.BrowseForFolder (&H0, _
    21. "Bitte wählen Sie den Ordner:", BIF_editbox + BIF_returnonlyfsdirs)
    23. 'Definition des Quellordners (sourceFolder), der vorher über die BrowseForFolder-Methode ermittelt wurde
    24. If InStr(1, TypeName(objStartFolder), "Folder") > 0 Then
    25. sourceFolder = objStartFolder.ParentFolder.ParseName(objStartFolder.Title).Path
    26. Else
    27. MsgBox "Ein Fehler trat auf: Der Zielordner kann nicht gelesen werden!"
    28. WScript.Quit
    29. End if
    31. 'Initialisierung des Zählers
    32. intZahl = "0"
    34. 'Deklaration des "GetObject"
    35. Set objWMI = GetObject("winmgmts://./root/cimv2")
    37. 'Start der For..Next Schleife, in der jede File des gewählten Ordners überprüft wird
    38. For Each File In fso.GetFolder(sourceFolder).Files
    40. 'Ermitteln des Sicherheitsobjektes über WMI
    41. objWMI.Get("Win32_LogicalFileSecuritySetting='" & File & "'").GetSecurityDescriptor objSD
    43. 'If..Schleife für die Löschung der gewünschten Dateien
    44. 'objSD.Owner.Name = Dateibesitzer
    45. 'objSD.Owner.Domain = Domäne des Besitzers
    46. If objSD.Owner.Name = Owner Then
    48. 'MsgBox mit einer Ja/Nein-Abfrage, ob die Datei gelöscht werden soll
    49. strMbox = MsgBox("Möchten Sie die Datei " & "'" & File.Name & "'" & " löschen?",4)
    51. 'Wenn Ja, Datei wird gelöscht und die Variable "ListFileOwner" mit Daten gefüllt
    52. If strMbox = 6 Then
    54. ListFileOwner = ListFileOwner & vbCrLf & File.Name
    55. File.Delete
    56. intZahl = intZahl + 1
    58. End If
    60. End If
    62. Next
    64. Const ForReading = 1, ForWriting = 2, ForAppending = 8
    66. 'Abschließend wird eine Textdatei mit dem Ergebnis der Löschung erstellt
    67. 'Die Datei hat die Erweiterung ".txt" und wird nach dem Besitzer der Dateien benannt
    68. 'Gespeichert wird die Datei in dem Ordner, der zuvor durchsucht wurde
    69. If intZahl = "0" Then
    70. Set oFile = fso.OpenTextFile(sourceFolder & "\" & Owner & ".txt",8,true)
    71. oFile.WriteLine "===================================================================="
    72. oFile.WriteLine "Am " & Day(Now) & "." & Month(Now) & "." & Year(Now) & " um " & Hour(Now) & ":" & Minute(Now) & ":" & Second(Now) _
    73. & " wurden keine Dateien von " & "'" & objSD.Owner.Name & "'" & " gelöscht!"
    74. oFile.WriteLine ""
    75. oFile.WriteLine "===================================================================="
    76. oFile.close
    77. Else
    78. If intZahl > 1 Then
    79. Set oFile = fso.OpenTextFile(sourceFolder & "\" & Owner & ".txt",8,true)
    80. oFile.WriteLine "===================================================================="
    81. oFile.WriteLine "Am " & Day(Now) & "." & Month(Now) & "." & Year(Now) & " um " & Hour(Now) & ":" & Minute(Now) & ":" & Second(Now) _
    82. & " wurden " & intZahl & " Dateien von " & "'" & objSD.Owner.Name & "'" & " gelöscht!"
    83. oFile.WriteLine ""
    84. oFile.WriteLine "Folgende Dateien wurden gelöscht:"
    85. oFile.WriteLine ListFileOwner
    86. oFile.WriteLine "===================================================================="
    87. oFile.close
    88. Else
    89. Set oFile = fso.OpenTextFile(sourceFolder & "\" & Owner & ".txt",8,true)
    90. oFile.WriteLine "===================================================================="
    91. oFile.WriteLine "Am " & Day(Now) & "." & Month(Now) & "." & Year(Now) & " um " & Hour(Now) & ":" & Minute(Now) & ":" & Second(Now) _
    92. & " wurde " & intZahl & " Datei von " & "'" & objSD.Owner.Name & "'" & " gelöscht!"
    93. oFile.WriteLine ""
    94. oFile.WriteLine "Folgende Datei wurde gelöscht:"
    95. oFile.WriteLine ListFileOwner
    96. oFile.WriteLine "===================================================================="
    97. oFile.close
    98. End If
    100. End If
    102. 'Scriptende
    103. WScript.Quit



    Viele Grüße
    p41n

Facebook
Telefonspende