Schleife beim Generieren von Text-Dateien

  • VBScript

Es gibt 3 Antworten in diesem Thema. Der letzte Beitrag () ist von Sachsenbauch.

    Schleife beim Generieren von Text-Dateien

    Hallo Freunde,
    ich komme nicht mehr weiter bei meinem Konstrukt.
    Und zwar möchte ich aus einer Datenquelle und einen Vorlagetext (beides Textdateien) HTML-Dateien regenieren. Ähnlich der Serienbrief-Funktion sollen in der Vorlagedatei #PLATZHALTER# durch Textstrings aus der Datendatei ersetzt werden. Hierzu wird bei mir eien temporäre Datei angelegt, in der dann die Platzhalter ersetzt werden. Am Ende erfolgt eine Umbenennung in das Endprodukt - eine durch die Nummer gekennzeichnete HTL-Datei beliebigen Inhalts, aber eben den ersetzten PLATZHALTERn.
    Beim ersten Datensatz klappt dies schon ganz gut, aber es gelingt mir nicht einen Durchlauf zu coden, der mir für jeden Datensatz in der Datendatei eine HTML-Datei generiert. Es wäre schön wenn mir einer das helfen könnte.
    Hier zuerst der Aufbau der Datendatei

    Visual Basic-Quellcode

    1. Nummer;Latein;Deutsch;Fotos;Datum
    2. 2208;Aquilegia vulgaris;Akelei;28;15.03.2011
    3. 2100;Iris bakeriana;Schwertlilien;29;13.07.2011
    4. 2066;Delphinium uralense;Rittersporn;31;11.02.2010
    5. 1950;Lupinus angustifolius;Lupine;24;30.01.2008
    6. 2071;Paeonia officinalis;Pfingstrose;30;08.07.2011

    und hier das unvollständige Konstrukt HTMLGenerator.vbs:

    Visual Basic-Quellcode

    1. Set objFSO = CreateObject("Scripting.FileSystemObject")
    3. Set Datendatei=objFSO.OpenTextFile("Daten.txt", 1) ' For Reading
    4. set Vorlagedatei=objFSO.OpenTextFile("Vorlage.txt", 1) ' For Reading
    5. Set Tempdatei=objFSO.CreateTextFile("123tmp89.txt",2 ) '2 For Writing
    7. ' | i=0
    8. ' | t = Datendatei.ReadAll
    9. ' | myArr=Split(t, vbcrlf)
    10. ' | Zeile=myArr(i)
    12. ' FOR I = 1 To 5
    14. Datendatei.SkipLine '1. Zeile überspringen
    15. u=Datendatei.Readline
    16. Arr = Split (u, ";")
    18. ' Ersatz für die #PLATZHALTER#
    19. Nummer=Arr(0)
    20. Latein=Arr(1)
    21. Deutsch=Arr(2)
    23. Do until Vorlagedatei.AtEndofStream
    24. Tempdatei.WriteLine(Vorlagedatei.Readline)
    25. Loop
    27. Tempdatei.close
    28. Vorlagedatei.Close
    30. ' Anlegen einer Tempdatei
    31. Set Tempdatei=objFSO.OpenTextFile("123tmp89.txt", 1) ' For Reading
    32. strText = Tempdatei.ReadAll
    34. Set Tempdatei=objFSO.OpenTextFile("123tmp89.txt", 2) ' For Writing
    36. ' #PLATZHALTER' in der Vorlage.txt
    37. strText1 = Replace(strText, "#NUMMER#", Nummer)
    38. strText2 = Replace(strText1, "#LATEIN#" , Latein)
    39. strText3 = Replace(strText2, "#DEUTSCH#", Deutsch)
    40. Tempdatei.Write strText3
    42. Datendatei.Close
    43. Set Tempdatei=objFSO.OpenTextFile("123tmp89.txt", 1) ' For Reading
    45. ' kopieren der Tempdatei auf die Ausgabedatei und weiterarbeiten mit dieser
    46. Set Ausgabedatei=objFSO.CreateTextFile(Nummer & ".html")
    48. Do until Tempdatei.AtEndofStream
    49. Ausgabedatei.WriteLine(Tempdatei.Readline)
    50. Loop
    52. Tempdatei.close 'wird nicht gelöscht, da immer weider neu erstellt...
    53. Ausgabedatei.Close
    55. '| i =i + 1
    56. '| NEXT


    Mein getesteter Vorschlag funktioniert natürlich nicht - Erkenntlich am '|

    Danke im voraus

    Micha :?:

    Dieser Beitrag wurde bereits 1 mal editiert, zuletzt von „Sachsenbauch“ ()

    Versuch' mal damit:

    Quellcode

    1. vorlage.txt (Testdatei)
    3. Die Nummer ist: #NUMMER#
    4. Lateinisch : #LATEIN#
    5. Deutsch : #DEUTSCH#


    Visual Basic-Quellcode

    1. Set objFSO = CreateObject("Scripting.FileSystemObject")
    3. Set Datendatei = objFSO.OpenTextFile("Daten.txt", 1) ' For Reading
    4. Set Vorlagedatei = objFSO.OpenTextFile("Vorlage.txt", 1) ' For Reading
    6. 'Vorlage lesen
    7. Temp = Vorlagedatei.ReadAll()
    8. Vorlagedatei.Close
    10. Datendatei.SkipLine '1. Zeile überspringen
    11. Do Until Datendatei.AtEndofStream
    13. u=Datendatei.Readline
    14. Arr = Split (u, ";")
    16. ' Ersatz für die #PLATZHALTER#
    17. Nummer =Arr (0)
    18. Latein = Arr(1)
    19. Deutsch = Arr(2)
    21. ' #PLATZHALTER' in der Vorlage.txt
    22. Ausgabe = Temp
    23. Ausgabe = Replace(Ausgabe, "#LATEIN#" , Latein)
    24. Ausgabe = Replace(Ausgabe, "#DEUTSCH#", Deutsch)
    25. Ausgabe = Replace(Ausgabe, "#NUMMER#", Nummer)
    28. Set Ausgabedatei=objFSO.CreateTextFile(Nummer & ".html")
    29. Ausgabedatei.Writeline (Ausgabe)
    30. Ausgabedatei.Close
    31. Loop
    32. Datendatei.Close

    Hallo Eierlein,
    wie immer hat mich Deine kompetente Lösung sehr beglückt erfreut. Der Probelauf lief zur besten Zufriedenheit und generierte mir die gewünschten Dateien.
    Freundliche Grüße aus Sachsen
    Micha:el

Facebook