Fraktale: Das Sierpinski-Dreieck

    • VB6

    Es gibt 4 Antworten in diesem Thema. Der letzte Beitrag () ist von ThePlexian.

      Fraktale: Das Sierpinski-Dreieck

      Folgender Code zeichnet ein Sierpinski-Dreieck bis
      zur achten Iterationsstufe. Controls werden nicht
      benötigt:

      Visual Basic-Quellcode

      1. ' Sierpinski-Dreieck
      2. ' Copyright © 2012 by Neptun
      4. Option Explicit
      6. Private Type POINTAPI
      7. x As Long
      8. y As Long
      9. End Type
      11. Private Type PtSng
      12. x As Single
      13. y As Single
      14. End Type
      16. Private Type Triple
      17. PtList(2) As PtSng
      18. End Type
      20. Private Declare Function Polygon Lib "gdi32" (ByVal hdc As Long, lpPoint As POINTAPI, ByVal nCount As Long) As Long
      22. Private Triangle1() As Triple
      23. Private Stage&
      25. Private Sub Form_Load()
      26. ' Einstellungen Form
      28. With Me
      29. .ScaleMode = vbPixels
      30. .Caption = "Sierpinski-Dreieck"
      31. .WindowState = vbMaximized
      32. .KeyPreview = True
      33. End With
      35. End Sub
      37. Private Sub Form_Activate()
      39. ' Stufe abfragen
      40. Stage = Val(InputBox("Iterationsstufe? (0 - 8)", Me.Caption, 6))
      41. Me.MousePointer = vbHourglass
      42. ' Stufe begrenzen
      43. If Stage < 0 Then
      44. Stage = 0
      45. ElseIf Stage > 8 Then
      46. Stage = 8
      47. End If
      48. Call CalcTriangle ' Rechnen
      49. Call DrawTriangle ' Zeichnen
      50. Me.MousePointer = vbDefault
      52. End Sub
      54. Private Sub CalcTriangle()
      55. ' Dreiecke berechnen
      57. Dim i&, j&, k&, IT&, g&
      58. Dim S!, Rand!, SW!, SH!, XP!, YP!
      59. Dim Triangle2() As Triple
      61. Rand = 8 ' Randabstand
      62. SW = Me.ScaleWidth
      63. SH = Me.ScaleHeight
      64. S = (SH - 2 * Rand) / Sqr(3)
      65. ReDim Triangle1(0)
      66. ' 1. Dreieck belegen
      67. For i = 0 To 2
      68. With Triangle1(0).PtList(i)
      69. .x = SW / 2 + Choose(i + 1, 0, -S, S)
      70. .y = IIf(i = 0, Rand, SH - Rand)
      71. End With
      72. Next i
      74. ' Alle Iterations-Stufen durchlaufen
      75. For IT = 1 To Stage
      77. ' Arrays anlegen
      78. g = UBound(Triangle1)
      79. ReDim Triangle2(g)
      80. Triangle2 = Triangle1
      81. ReDim Triangle1((g + 1) * 3 - 1)
      83. ' Dreiecke berechnen und eintragen
      84. For i = 0 To g
      85. For j = 0 To 2
      86. With Triangle1(3 * i + j)
      87. For k = 0 To 2
      88. With Triangle2(i)
      89. XP = .PtList(j).x
      90. YP = .PtList(j).y
      91. If k > 0 Then
      92. With .PtList((j + k) Mod 3)
      93. XP = (XP + .x) / 2
      94. YP = (YP + .y) / 2
      95. End With
      96. End If
      97. End With
      98. With .PtList(k)
      99. .x = XP
      100. .y = YP
      101. End With
      102. Next k
      103. End With
      104. Next j
      105. Next i
      107. Next IT
      109. ' Speicher freigeben
      110. Erase Triangle2
      112. End Sub
      114. Private Sub DrawTriangle()
      115. ' Dreiecke zeichnen
      117. Dim i&, j&, Figur(2) As POINTAPI
      119. With Me
      120. .Caption = .Caption & Space$(10) & "Stufe " & Stage
      121. .BackColor = vbWhite ' Hintergrundfarbe
      122. .ForeColor = vbRed ' Kantenfarbe Dreiecke
      123. .FillColor = vbRed ' Füllfarbe Dreiecke
      124. .FillStyle = vbFSSolid
      125. .AutoRedraw = True
      126. .Cls
      127. ' Alle Dreiecke durchgehen
      128. For i = 0 To UBound(Triangle1)
      129. ' Eckpunkte übertragen
      130. For j = 0 To 2
      131. With Triangle1(i).PtList(j)
      132. Figur(j).x = .x
      133. Figur(j).y = .y
      134. End With
      135. Next j
      136. ' Dreieck zeichnen
      137. Call Polygon(.hdc, Figur(0), 3)
      138. Next i
      139. .FillStyle = vbFSTransparent
      140. End With
      142. End Sub
      144. Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
      145. ' Beenden
      147. If KeyCode = vbKeyEscape Then Unload Me
      149. End Sub
      Bilder

      • DREIECK2.JPG

        53,8 kB, 819×710, 329 mal angesehen
      Gruss,

      Neptun

      Dieser Beitrag wurde bereits 1 mal editiert, zuletzt von „Neptun“ ()

      Hallo,

      Der Coode ist wircklich Kunst des Programmierens aber mal ne kleine Frage am Rande falls erlaubt? Kann ich die Größe und die Richtung des Dreicks so wie die farben der Inneren Dreiecke auch Vaiieren??

      LG, Herbrich

      In den Tipps&Tricks und im Sourcecode-Austauschist's erlaubt, sofern es Erweiterungen gibt, in allen Bereichen, wenn es weitere Fragen zu einem expliziten Thema gibt.
      Der Code ist in .Net trivial umzusetzen: Bis zu einem gewissen Grad einfach ein gleichseitiges Dreieck in vier Dreiecke zerlegen (Tipp: höhe/2, breite/2 sind zwei wichtige Orte) und dieses dann über die Eckpunkte darstellen.

      Gruß
      ~blaze~

      @~blaze~ : Ich hab sowas mal implementiert, und dabei das Lindenmayer-System genutzt, geht mathematisch gesehen einfacher, da so gleich mehrere Fraktale abgebildet werden können ^^
      »There's no need to "teach" atheism. It's the natural result of education without indoctrination.« — Ricky Gervais