Hi Leute,

wie kann ich mit vb unter windows abfragen, welche Programme und Prozesse gerade laufen??? Geht es überhaupt???

KKK

Sicher, alles ist möglich (naja fast alles)

mit diesem Code kannst du sehen welche Prozesse grade am laufen sind
Zuerst das was du in einem Modul definieren musst :

-----------------------------------------------------------------------

Public Const TH32CS_SNAPPROCESS As Long = 2&
Public Const MAX_PATH As Long = 260

Public Type PROCESSENTRY32
dwSize As Long
cntUsage As Long
th32ProcessID As Long
th32DefaultHeapID As Long
th32ModuleID As Long
cntThreads As Long
th32ParentProcessID As Long
pcPriClassBase As Long
dwFlags As Long
szExeFile As String * MAX_PATH
End Type


Public Declare Function CreateToolhelp32Snapshot Lib "kernel32" _
(ByVal lFlags As Long, ByVal lProcessID As Long) As Long

Public Declare Function ProcessFirst Lib "kernel32" _
Alias "Process32First" _
(ByVal hSnapShot As Long, uProcess As PROCESSENTRY32) As Long

Public Declare Function ProcessNext Lib "kernel32" _
Alias "Process32Next" _
(ByVal hSnapShot As Long, uProcess As PROCESSENTRY32) As Long

Public Declare Sub CloseHandle Lib "kernel32" _
(ByVal hPass As Long)

-----------------------------------------------------------------------

Das kommt ins Modul. Nun brauchst dur nur noch ne Funtkion die alles abfragt das Muss dann so aussehen :

------------------------------------------------------------------------

Dim hSnapShot As Long
Dim Process As PROCESSENTRY32
Dim i As Long

hSnapShot = CreateToolhelp32Snapshot(TH32CS_SNAPPROCESS, 0&)

If hSnapShot = -1 Then Exit Sub 'Oder Function, je nachdem

Process.dwSize = Len(Process)
i = ProcessFirst(hSnapShot, Process)

Do While i

List1.AddItem Process.szExeFile 'Oder ein Array oder sonst was ...
i = ProcessNext(hSnapShot, Process)

Loop

Call CloseHandle(hSnapShot)

------------------------------------------------------------------------

Tja und das wars auch