Überprüfen, ob ein best. Programm gestartet wurde

Gast · 22. April 2003, 11:16

Huhu

Ich möchte gerne, dass mein Programm darauf wartet, das z.B. Notepad gestartet wird und erst dann weitermacht.
Ich stell mir das mit Hilfe eines timers vor, der alle x Zeiteinheiten überprüft, ob notepad.exe im Speicher ist und wenn ja, dann eine Aktion ausführt. Wenn nein, dann geht der Timer wieder auf Null und zäht erneut.

Wie krieg ich aber raus, ob notepad.exe gestartet ist?

Danke für die Hilfe,

Scrapie

Marcus Gräfe · 24. April 2003, 21:05

Mit folgender Funktion:

<pre>Public Function FindExe(ExeName As String) As Boolean
Dim hSnapShot As Long
Dim uProcess As PROCESSENTRY32
Dim RetVal As Long

FindExe = False

hSnapShot = CreateToolhelpSnapshot(TH32CS_SNAPPROCESS, 0&)

uProcess.dwSize = Len(uProcess)
RetVal = ProcessFirst(hSnapShot, uProcess)

Do While RetVal <> 0
uProcess.szExeFile = Left$(uProcess.szExeFile, InStr(uProcess.szExeFile, Chr$(0)) - 1)
If InStr(1, uProcess.szExeFile, ExeName, vbTextCompare) Then FindExe = True
RetVal = ProcessNext(hSnapShot, uProcess)
Loop

CloseHandle hSnapShot
End Function

</PRE>

Du benötigst auch noch folgende API Deklarationen:

<PRE>Public Const TH32CS_SNAPPROCESS As Long = 2&
Public Const MAX_PATH As Integer = 260

Public Type PROCESSENTRY32
dwSize As Long
cntUsage As Long
th32ProcessID As Long
th32DefaultHeapID As Long
th32ModuleID As Long
cntThreads As Long
th32ParentProcessID As Long
pcPriClassBase As Long
dwFlags As Long
szExeFile As String * MAX_PATH
End Type

Public Declare Function CreateToolhelpSnapshot Lib "kernel32" Alias _
"CreateToolhelp32Snapshot" (ByVal lFlags As Long, ByVal lProcessID As Long) As Long
Public Declare Function ProcessFirst Lib "kernel32" Alias "Process32First" _
(ByVal hSnapShot As Long, uProcess As PROCESSENTRY32) As Long
Public Declare Function ProcessNext Lib "kernel32" Alias "Process32Next" _
(ByVal hSnapShot As Long, uProcess As PROCESSENTRY32) As Long
Public Declare Sub CloseHandle Lib "kernel32" (ByVal hPass As Long)

</pre>

Gast · 28. April 2003, 09:40

Huhu

Danke für die Antwort.
Ich werds heute Abend mal testen,

Thx!

Überprüfen, ob ein best. Programm gestartet wurde

Überprüfen, ob ein best. Programm gestartet wurde

Benutzer online 1

Ähnliche Themen

2 Benutzer haben hier geschrieben