Alle Netzwerkbenutzer auslesen

  • VB6

Es gibt 8 Antworten in diesem Thema. Der letzte Beitrag () ist von Mufasa.

    Alle Netzwerkbenutzer auslesen

    Hi Leute,

    ich möchte einen Dateimanager mit zusätzlichen funktionen schreiben. Unter anderem eben eine Art Netzwerkumgebung. Aber wie kann ich alle am Netzwerkteilnehmenden Computer auflisten lassen???

    Bitte um HILFE

    KKK

    Ich glaub das geht mit VB nich weil man dafür NetGetQueryInformation aufrufen muss und dann von dieser Funktion in einen Buffer den Zeiger auf eine Struktur zugewiesen bekommt und das kannst du in VB nich lösen (glaub ich, kann sein das ich mich irre !)

    Dieser Beitrag wurde bereits 1 mal editiert, zuletzt von „Unknown“ ()

    Doch klar geht das, und zwar so:

    Visual Basic-Quellcode

    1. Private Declare Function WNetOpenEnum Lib "mpr.dll" Alias _
    2. "WNetOpenEnumA" (ByVal dwScope As Long, ByVal dwType As _
    3. Long, ByVal dwUsage As Long, lpNetResource As Any, lphEnum _
    4. As Long) As Long
    6. Private Declare Function WNetEnumResource Lib "mpr.dll" Alias _
    7. "WNetEnumResourceA" (ByVal hEnum As Long, lpcCount As Long, _
    8. lpBuffer As NETRESOURCE, lpBufferSize As Long) As Long
    10. Private Declare Function WNetCloseEnum Lib "mpr.dll" (ByVal hEnum _
    11. As Long) As Long
    13. Private Declare Function lstrlen Lib "kernel32" Alias "lstrlenA" _
    14. (ByVal lpString As Any) As Long
    16. Private Type NETRESOURCE
    17. dwScope As Long
    18. dwType As Long
    19. dwDisplayType As Long
    20. dwUsage As Long
    21. pLocalName As Long
    22. pRemoteName As Long
    23. pComment As Long
    24. pProvider As Long
    25. End Type
    27. Private Type NETRESOURCE_REAL
    28. dwScope As Long
    29. dwType As Long
    30. dwDisplayType As Long
    31. dwUsage As Long
    32. sLocalName As String
    33. sRemoteName As String
    34. sComment As String
    35. sProvider As String
    36. End Type
    38. Private Const RESOURCE_GLOBALNET As Long = &H2&
    40. Private Const RESDTYPE_SERVER& = &H2
    42. Private Const RESOURCETYPE_ANY As Long = &H0&
    44. Private Const RESOURCEUSAGE_ALL As Long = &H0&
    45. Private Const RESOURCEUSAGE_CONTAINER As Long = &H2&
    47. Private Const NO_ERROR = 0
    48. Private Const ERROR_MORE_DATA = 234
    49. Private Const RESOURCE_ENUM_ALL As Long = &HFFFF
    52. Public Sub GetLanIPs()
    53. Const MAX_RESOURCES = 256
    54. Const NOT_A_CONTAINER = -1
    56. Dim bFirstTime As Boolean
    57. Dim lRet&, hEnum&, lCnt&, lMin&, lLen&, l&, lBufSize&, lLastIx&
    58. Dim nRem$, F$
    59. Dim uNetApi(0 To MAX_RESOURCES) As NETRESOURCE
    60. Dim uNet() As NETRESOURCE_REAL
    61. Dim MaxUBound As Long
    63. bFirstTime = True
    65. Do
    66. If bFirstTime Then
    67. lRet = WNetOpenEnum(RESOURCE_GLOBALNET, RESOURCETYPE_ANY, RESOURCEUSAGE_ALL, ByVal 0&, hEnum)
    68. bFirstTime = False
    69. Else
    70. If uNet(lLastIx).dwUsage And RESOURCEUSAGE_CONTAINER Then
    71. lRet = WNetOpenEnum(RESOURCE_GLOBALNET, RESOURCETYPE_ANY, RESOURCEUSAGE_ALL, uNet(lLastIx), hEnum)
    72. Else
    73. lRet = NOT_A_CONTAINER
    74. hEnum = 0
    75. End If
    76. lLastIx = lLastIx + 1
    77. End If
    79. If lRet = NO_ERROR Then
    80. lCnt = RESOURCE_ENUM_ALL
    81. Do
    82. lBufSize = UBound(uNetApi) * Len(uNetApi(0)) / 2
    83. lRet = WNetEnumResource(hEnum, lCnt, uNetApi(0), lBufSize)
    84. If lCnt > 0 Then
    85. ReDim Preserve uNet(0 To lMin + lCnt - 1) As NETRESOURCE_REAL
    86. For l = 0 To lCnt - 1
    87. uNet(lMin + l).dwScope = uNetApi(l).dwScope
    88. uNet(lMin + l).dwType = uNetApi(l).dwType
    89. uNet(lMin + l).dwDisplayType = uNetApi(l).dwDisplayType
    90. uNet(lMin + l).dwUsage = uNetApi(l).dwUsage
    91. If uNetApi(l).pLocalName Then
    92. lLen = lstrlen(uNetApi(l).pLocalName)
    93. uNet(lMin + l).sLocalName = Space$(lLen)
    94. CopyMemory ByVal uNet(lMin + l).sLocalName, ByVal uNetApi(l).pLocalName, lLen
    95. End If
    96. If uNetApi(l).pRemoteName Then
    97. lLen = lstrlen(uNetApi(l).pRemoteName)
    98. uNet(lMin + l).sRemoteName = Space$(lLen)
    99. CopyMemory ByVal uNet(lMin + l).sRemoteName, ByVal uNetApi(l).pRemoteName, lLen
    100. End If
    101. If uNetApi(l).pComment Then
    102. lLen = lstrlen(uNetApi(l).pComment)
    103. uNet(lMin + l).sComment = Space$(lLen)
    104. CopyMemory ByVal uNet(lMin + l).sComment, ByVal uNetApi(l).pComment, lLen
    105. End If
    106. If uNetApi(l).pProvider Then
    107. lLen = lstrlen(uNetApi(l).pProvider)
    108. uNet(lMin + l).sProvider = Space$(lLen)
    109. CopyMemory ByVal uNet(lMin + l).sProvider, ByVal uNetApi(l).pProvider, lLen
    110. End If
    111. Next l
    112. End If
    113. lMin = lMin + lCnt
    114. Loop While lRet = ERROR_MORE_DATA
    115. End If
    116. If hEnum Then l = WNetCloseEnum(hEnum)
    117. Loop While lLastIx < lMin
    119. On Error Resume Next
    120. MaxUBound = UBound(uNet)
    121. If Err.Number = 0 Then
    122. For l = 0 To UBound(uNet)
    123. If uNet(l).dwDisplayType = RESDTYPE_SERVER Then
    124. F = uNet(l).sRemoteName
    125. F = Replace$(F, "\", vbNullString)
    126. F = Replace$(F, "/", vbNullString)
    127. F = LCase(F)
    128. If F vbNullString Then
    129. List1.Add F
    130. End If
    131. End If
    132. Next l
    133. End If
    134. On Error GoTo 0
    135. End Sub
    Besucht auch mein anderes Forum:
    Das Amateurfilm-Forum

    Dieser Beitrag wurde bereits 1 mal editiert, zuletzt von „Agent“ ()

    Ich habe vergessen, die CopyMemory API zu deklarieren:

    Public Declare Sub CopyMemory Lib "kernel32" Alias "RtlMoveMemory" (ByRef Destination As Any, ByRef Source As Any, ByVal Length As Long)
    Besucht auch mein anderes Forum:
    Das Amateurfilm-Forum

    Den oberen Teil (bis zum Strich) schreibst du in ein Modul, die GetLanIPs-Prozedur in ein Formular. Dann machst du im Formular einen Button und eine ListBox (List1) und benutzt folgenden Code:

    Private Sub Command1_Click()
    GetLanIPs
    End Sub
    Besucht auch mein anderes Forum:
    Das Amateurfilm-Forum

    Thema Wiederbelebung :-)

    Jetzt muss ich das Thema mal wiederbeleben.... sitze nämlich jetzt gerade vor dem gleichen bzw. einem ähnlichen Problem....

    Vorneweg: Ich bin absoluter Neuling und habe noch nie VB geschrieben :( Also bitte gaaaaanz laaaangsam für Dummies ;)

    Ich soll also für die Arbeit ein Progrämmchen machen, dass alle Netzwerk-UP&P-Geräte mit IP anzeigt. Ideal wäre es wenn man auf jedes Gerät Doppelklicken kann und sich diese IP dann im Standardbrowser öffnet. Aber das wäre dann der zweite Schritt....

    @Marcus: Komm ich hier mit Deinem Code hier zum Ziel? Wenn ja wie mach ich das damit? Habe wirklich null Ahnung bisher.... Könntest Du das vielleicht als kleines Projekt hochladen? Wäre super!!

    @All: Oder gibt es hier oder irgendwo sonst schon einen halbwegs fertigen Code für sowas den ich anpassen könnte an die Bedürfnisse? Ich meine jetzt Farbgebung und so....

    Hmmm.....schließlich fängt ja jeder mal klein an ;)

    Danke allen schon mal im Vorraus!!

Facebook
Telefonspende