Shape auf anderes aufspringen lassen

  • VB6

Es gibt 5 Antworten in diesem Thema. Der letzte Beitrag () ist von Neptun.

    Shape auf anderes aufspringen lassen

    Hei Leute ,
    ICh bin zur Zeit dran mir das Spiel Super mario nach zu machen komme aber am anfang schon nicht weiter.
    Ich hab den Mario in einer Pic.box drin diese lässt sich auch frei nach meinem Willen bewegen .
    Nun zum problem ich weis nich wie ich den code für das springen von mario auf eine Shape-box schreiben soll.

    Vielen dank schon mal im Vorraus

    Hallo baggi,
    für die Steuerung des Sprungs verwendest du am besten
    ein Timer-Control (Anfangsgeschwindigkeit festlegen
    und bei jedem Timer-Aufruf die Top der Picturebox
    verkleinern). Um festzustellen, ob die Figur auf einem
    Shape gelandet ist, muss man die Koordinaten der Picturebox
    mit den Koordinaten der Shapes vergleichen und gegebenenfalls
    stoppen. Ich habe auch noch ein Beispiel auf meiner
    Festplatte. Wenn Interesse besteht, werde ich es mal raussuchen.
    Gruss,

    Neptun

    Hallo baggi,
    hier der Code. Gesteuert wird über die Pfeiltasten:

    Visual Basic-Quellcode

    1. ' Copyright © 2010 by Neptun
    3. ' Controls: 1 * Shape mit Index = 0
    4. ' 1 * Timer, 1 * PictureBox
    6. Option Explicit
    8. Private Type RECT
    9. Left As Long
    10. Top As Long
    11. Right As Long
    12. Bottom As Long
    13. End Type
    15. Private Declare Function SetRect Lib "user32" (lpRect As RECT, ByVal X1 As Long, ByVal Y1 As Long, ByVal X2 As Long, ByVal Y2 As Long) As Long
    16. Private Declare Function IntersectRect Lib "user32" (lpDestRect As RECT, lpSrc1Rect As RECT, lpSrc2Rect As RECT) As Long
    18. Private Speed As Single, XRi As Single
    20. Private Sub Form_Load()
    22. Dim i As Long, Hoehe As Single
    24. Me.ScaleMode = vbPixels
    25. Me.BackColor = RGB(200, 200, 255)
    26. Me.KeyPreview = True
    27. Speed = 0
    28. XRi = 0
    29. With Picture1
    30. .BorderStyle = vbBSNone
    31. .BackColor = vbRed
    32. .Move 390, 10, 40, 70
    33. End With
    34. For i = 0 To 8
    35. Hoehe = 20 + i * 40
    36. If i > 0 Then Load Shape1(i)
    37. With Shape1(i)
    38. .Shape = vbShapeRectangle
    39. .FillStyle = vbFSSolid
    40. .FillColor = RGB(128, 70, 0)
    41. .Move 50 + 70 * i, Me.ScaleHeight - Hoehe, 20, Hoehe
    42. .Visible = True
    43. End With
    44. Next i
    45. Timer1.Interval = 15
    46. Timer1.Enabled = True
    48. End Sub
    50. Private Sub Form_KeyDown(KeyCode As Integer, Shift As Integer)
    52. Select Case KeyCode
    53. Case vbKeyRight ' nach rechts laufen
    54. XRi = 4
    55. Case vbKeyLeft ' nach links laufen
    56. XRi = -4
    57. Case vbKeyUp ' hochspringen, wenn auf dem Boden
    58. If Speed = 0 Then Speed = -5
    59. End Select
    61. End Sub
    63. Private Sub Form_KeyUp(KeyCode As Integer, Shift As Integer)
    65. If KeyCode = vbKeyRight Or KeyCode = vbKeyLeft Then XRi = 0
    67. End Sub
    69. Private Sub Timer1_Timer()
    71. Dim flgGround As Boolean, i As Long, j As Long
    72. Dim R1 As RECT, R2 As RECT, Ground As Single
    74. ' Rechts / Links laufen
    75. If XRi <> 0 Then Picture1.Left = Picture1.Left + XRi
    77. ' Sprung Steigphase
    78. If Speed < 0 Then
    79. Picture1.Top = Picture1.Top + Speed
    80. Speed = Speed + 0.2
    81. If Speed > 0 Then Speed = 0
    82. Exit Sub
    83. End If
    85. ' Freier Fall
    86. Ground = Picture1.Top + Picture1.Height
    87. For i = 1 To Speed + 1
    88. If Ground >= Me.ScaleHeight Then
    89. ' Boden erreicht
    90. Speed = 0
    91. Exit Sub
    92. End If
    93. flgGround = False
    94. ' Alle Shapes durchgehen
    95. For j = 0 To Shape1.UBound
    96. ' Figur auf Höhe von Shape?
    97. If Ground = Shape1(j).Top Then
    98. With Shape1(j) ' Koordinaten Shape eintragen
    99. Call SetRect(R1, .Left, .Top, .Left + .Width, .Top + .Height)
    100. End With
    101. With Picture1 ' Koordinaten Figur eintragen
    102. Call SetRect(R2, .Left, Ground, .Left + .Width, Ground + 1)
    103. End With
    104. ' Berührt die Figur ein Shape?
    105. If IntersectRect(R1, R1, R2) <> 0 Then
    106. ' Boden erreicht
    107. flgGround = True
    108. Speed = 0
    109. Exit For
    110. End If
    111. End If
    112. Next j
    113. ' Kein Boden? 1 Pixel fallen lassen
    114. If flgGround = False Then Ground = Ground + 1
    115. Next i
    116. ' Kein Boden? Fallgeschwindigkeit erhöhen
    117. If flgGround = False Then Speed = Speed + 0.3
    118. Picture1.Top = Ground - Picture1.Height
    120. End Sub

    Grundsätzlich ist sind Shapes nicht die beste Lösung.
    Besser ist es, das Spielfeld in kleine Quadrate einzuteilen
    und für jedes Quadrat in einem 2D-Array zu hinterlegen, ob
    es begehbar ist, oder nicht.
    Gruss,

    Neptun

    Dieser Beitrag wurde bereits 1 mal editiert, zuletzt von „Neptun“ ()

Facebook